net-analyzer/flow-tools: Revbump to fix compile and mysql dependency

Non-maintainer commit.

Original ebuild and patch by Robin Johnson <robbat2@gentoo.org>
Additional change for mysql dep by me

Bug: https://bugs.gentoo.org/674032
Bug: https://bugs.gentoo.org/665940
Package-Manager: Portage-2.3.60, Repoman-2.3.12
Signed-off-by: Brian Evans <grknight@gentoo.org>

1 files changed, 78 insertions, 0 deletions

diff --git a/net-analyzer/flow-tools/flow-tools-0.68.5.1-r10.ebuild b/net-analyzer/flow-tools/flow-tools-0.68.5.1-r10.ebuild
new file mode 100644
index 000000000000..9d62c33981ae
--- /dev/null
+++ b/net-analyzer/flow-tools/flow-tools-0.68.5.1-r10.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit user
+
+DESCRIPTION="library and programs to process reports from NetFlow data"
+HOMEPAGE="https://code.google.com/p/flow-tools/"
+SRC_URI="https://${PN}.googlecode.com/files/${P}.tar.bz2"
+
+LICENSE="BSD GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="debug libressl mysql postgres ssl static-libs"
+
+RDEPEND="sys-apps/tcp-wrappers
+	sys-libs/zlib
+	mysql? ( dev-db/mysql-connector-c:0= )
+	postgres? ( dev-db/postgresql:* )
+	ssl? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl:0= )
+	)"
+
+DEPEND="${RDEPEND}
+	sys-devel/flex
+	sys-devel/bison"
+
+DOCS=( ChangeLog README SECURITY TODO )
+
+PATCHES=(
+	"${FILESDIR}"/${P}-run.patch
+	"${FILESDIR}"/${P}-syslog.patch
+	"${FILESDIR}"/${P}-openssl11.patch
+)
+
+pkg_setup() {
+	pkg_douser
+}
+
+src_configure() {
+	econf \
+		$(use_enable static-libs static) \
+		$(usex mysql --with-mysql '') \
+		$(usex postgres --with-postgresql=yes --with-postgresql=no) \
+		$(usex ssl --with-openssl '') \
+		--sysconfdir=/etc/flow-tools
+}
+
+src_install() {
+	default
+
+	find "${D}" -name '*.la' -delete || die
+
+	exeinto /var/lib/flows/bin
+	doexe "${FILESDIR}"/linkme
+
+	keepdir /var/lib/flows/ft
+
+	newinitd "${FILESDIR}/flowcapture.initd" flowcapture
+	newconfd "${FILESDIR}/flowcapture.confd" flowcapture
+
+	fowners flows:flows /var/lib/flows
+	fowners flows:flows /var/lib/flows/bin
+	fowners flows:flows /var/lib/flows/ft
+
+	fperms 0755 /var/lib/flows
+	fperms 0755 /var/lib/flows/bin
+}
+
+pkg_preinst() {
+	pkg_douser
+}
+
+pkg_douser() {
+	enewgroup flows
+	enewuser flows -1 -1 /var/lib/flows flows
+}