net-dns/pdns-recursor: Version bump to 4.4.3

Package-Manager: Portage-3.0.17, Repoman-3.0.2
Signed-off-by: Sven Wegener <swegener@gentoo.org>

2 files changed, 89 insertions, 0 deletions

diff --git a/net-dns/pdns-recursor/Manifest b/net-dns/pdns-recursor/Manifest
index 4f0d1146b573..1c461dbb3fb2 100644
--- a/net-dns/pdns-recursor/Manifest
+++ b/net-dns/pdns-recursor/Manifest
@@ -1 +1,2 @@
 DIST pdns-recursor-4.4.2.tar.bz2 1396763 BLAKE2B f8dad7694ac13ed8d824ddaf613d1a001452ab2c08fcbb0e00d2b2258464b754809746b89998b818c44866f9e4b22c87c1cebf2da852fb7b6247ac6b9fd4b99d SHA512 31fdf62d87e5ee8f9570c6b738339bc8cc65c43800f18c7fb49aa5c53fc9ad76a1ddf02cc44f7129e06b41700b5cb3768ff8f81cc521c28147ea6538c73f8781
+DIST pdns-recursor-4.4.3.tar.bz2 1398743 BLAKE2B d9429ef22bb2b196e42da91332332b38dee9220d490c8adda686b0bc144e0981ea4418973f4304d6d964ef8f6ac4adcde4bd3e6d6b208c620440eab1b11a7fc0 SHA512 bac69cbaabc1b0de0def681e07f7e77954e0d487732cb46dc722f7869576a8a477a4011f78c9cc66b5e9b45455eb81534602b2834dc1ad42b85f5f2801915cbb
diff --git a/net-dns/pdns-recursor/pdns-recursor-4.4.3.ebuild b/net-dns/pdns-recursor/pdns-recursor-4.4.3.ebuild
new file mode 100644
index 000000000000..250051ea82e5
--- /dev/null
+++ b/net-dns/pdns-recursor/pdns-recursor-4.4.3.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( lua5-{1..4} luajit )
+
+inherit flag-o-matic lua-single
+
+DESCRIPTION="The PowerDNS Recursor"
+HOMEPAGE="https://www.powerdns.com/"
+SRC_URI="https://downloads.powerdns.com/releases/${P/_/-}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="debug dnstap libressl protobuf snmp sodium systemd test"
+REQUIRED_USE="${LUA_REQUIRED_USE}
+	dnstap? ( protobuf )"
+
+DEPEND="${LUA_DEPS}
+	protobuf? (
+		dev-libs/protobuf
+		>=dev-libs/boost-1.42:=
+	)
+	dnstap? ( dev-libs/fstrm )
+	systemd? ( sys-apps/systemd:0= )
+	snmp? ( net-analyzer/net-snmp )
+	sodium? ( dev-libs/libsodium:= )
+	libressl? ( dev-libs/libressl:= )
+	!libressl? ( dev-libs/openssl:= )
+	>=dev-libs/boost-1.35:="
+RDEPEND="${DEPEND}
+	!<net-dns/pdns-2.9.20-r1
+	acct-user/pdns
+	acct-group/pdns"
+BDEPEND="virtual/pkgconfig"
+
+S="${WORKDIR}"/${P/_/-}
+
+pkg_setup() {
+	lua-single_pkg_setup
+	filter-flags -ftree-vectorize
+}
+
+src_configure() {
+	econf \
+		--sysconfdir=/etc/powerdns \
+		--with-nod-cache-dir=/var/lib/powerdns \
+		--with-service-user=pdns \
+		--with-service-group=pdns \
+		--with-lua="${ELUA}" \
+		$(use_enable debug verbose-logging) \
+		$(use_enable systemd) \
+		$(use_enable dnstap dnstap) \
+		$(use_enable test unit-tests) \
+		$(use_with sodium libsodium) \
+		$(use_with protobuf) \
+		$(use_with snmp net-snmp)
+}
+
+src_install() {
+	default
+
+	mv "${D}"/etc/powerdns/recursor.conf{-dist,}
+
+	# set defaults: setuid=nobody, setgid=nobody
+	sed -i \
+		-e 's/^# set\([ug]\)id=$/set\1id=pdns/' \
+		-e 's/^# quiet=$/quiet=on/' \
+		-e 's/^# chroot=$/chroot=\/var\/lib\/powerdns/' \
+		"${D}"/etc/powerdns/recursor.conf
+
+	newinitd "${FILESDIR}"/pdns-recursor-r2 pdns-recursor
+}
+
+pkg_postinst() {
+	local old
+
+	for old in ${REPLACING_VERSIONS}; do
+		ver_test ${old} -lt 4.0.0-r1 || continue
+
+		ewarn "Starting with 4.0.0-r1 the init script has been renamed from precursor"
+		ewarn "to pdns-recursor, please update your runlevels accordingly."
+
+		break
+	done
+}