net-dns/pdns-recursor: Version bump to 4.3.4

Package-Manager: Portage-3.0.4, Repoman-3.0.1
Signed-off-by: Sven Wegener <swegener@gentoo.org>

2 files changed, 86 insertions, 0 deletions

diff --git a/net-dns/pdns-recursor/Manifest b/net-dns/pdns-recursor/Manifest
index 490ac9a1bcb1..d78a04ac4c7e 100644
--- a/net-dns/pdns-recursor/Manifest
+++ b/net-dns/pdns-recursor/Manifest
@@ -1 +1,2 @@
 DIST pdns-recursor-4.3.3.tar.bz2 1357853 BLAKE2B fa57776bbdb77d1f13f04fdd1fb5ceb07539f851704dc627443a7c814d6640b1e7890333b6d7214a201f5d3f83a54a7840adb6450ffb7696e58722625b7c57c5 SHA512 285f12d3cb2edaca7507dd9dad1356b60076d43af678458346489562ea8933a01d61d2430d5282b6afd213839ee684ad83e5f523c9a272f382d74ccc238bd9d5
+DIST pdns-recursor-4.3.4.tar.bz2 1359380 BLAKE2B b55829b843f3abc9394bcb943c223b24684ebe67854fbde8590aded09a8ef18d8b15d1e2ebe1b88d24833b8782266b1ce853d98c0ce510e115e8d16ce900ece2 SHA512 cfc34f42ed95c7fd2be1ab7ba172672e5e1db96b4ced171c1eae7bd60fb7db482aed928028811b133d326550de35c506a8fc480b12ae39ab7fa142408e0b42d8
diff --git a/net-dns/pdns-recursor/pdns-recursor-4.3.4.ebuild b/net-dns/pdns-recursor/pdns-recursor-4.3.4.ebuild
new file mode 100644
index 000000000000..cb9a0daba0e2
--- /dev/null
+++ b/net-dns/pdns-recursor/pdns-recursor-4.3.4.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+inherit flag-o-matic
+
+DESCRIPTION="The PowerDNS Recursor"
+HOMEPAGE="https://www.powerdns.com/"
+SRC_URI="https://downloads.powerdns.com/releases/${P/_/-}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="debug dnstap libressl luajit protobuf snmp sodium systemd"
+REQUIRED_USE="dnstap? ( protobuf )"
+
+DEPEND="!luajit? ( >=dev-lang/lua-5.1:= )
+	luajit? ( dev-lang/luajit:= )
+	protobuf? (
+		dev-libs/protobuf
+		>=dev-libs/boost-1.42:=
+	)
+	dnstap? ( dev-libs/fstrm )
+	systemd? ( sys-apps/systemd:0= )
+	snmp? ( net-analyzer/net-snmp )
+	sodium? ( dev-libs/libsodium:= )
+	libressl? ( dev-libs/libressl:= )
+	!libressl? ( dev-libs/openssl:= )
+	>=dev-libs/boost-1.35:="
+RDEPEND="${DEPEND}
+	!<net-dns/pdns-2.9.20-r1
+	acct-user/pdns
+	acct-group/pdns"
+BDEPEND="virtual/pkgconfig"
+
+S="${WORKDIR}"/${P/_/-}
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-4.3.1-boost-1.73.0.patch
+)
+
+pkg_setup() {
+	filter-flags -ftree-vectorize
+}
+
+src_configure() {
+	econf \
+		--sysconfdir=/etc/powerdns \
+		--with-lua=$(usex luajit luajit lua) \
+		$(use_enable debug verbose-logging) \
+		$(use_enable systemd) \
+		$(use_enable dnstap dnstap) \
+		$(use_with sodium libsodium) \
+		$(use_with protobuf) \
+		$(use_with snmp net-snmp)
+}
+
+src_install() {
+	default
+
+	mv "${D}"/etc/powerdns/recursor.conf{-dist,}
+
+	# set defaults: setuid=nobody, setgid=nobody
+	sed -i \
+		-e 's/^# set\([ug]\)id=$/set\1id=pdns/' \
+		-e 's/^# quiet=$/quiet=on/' \
+		-e 's/^# chroot=$/chroot=\/var\/lib\/powerdns/' \
+		"${D}"/etc/powerdns/recursor.conf
+
+	newinitd "${FILESDIR}"/pdns-recursor-r2 pdns-recursor
+}
+
+pkg_postinst() {
+	local old
+
+	for old in ${REPLACING_VERSIONS}; do
+		ver_test ${old} -lt 4.0.0-r1 || continue
+
+		ewarn "Starting with 4.0.0-r1 the init script has been renamed from precursor"
+		ewarn "to pdns-recursor, please update your runlevels accordingly."
+
+		break
+	done
+}