net-irc/konversation: 20.12.3 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 74 insertions, 0 deletions

diff --git a/net-irc/konversation/Manifest b/net-irc/konversation/Manifest
index 1c591d124e4f..ac535129500c 100644
--- a/net-irc/konversation/Manifest
+++ b/net-irc/konversation/Manifest
@@ -1,2 +1,3 @@
 DIST konversation-1.7.7.tar.xz 3357584 BLAKE2B 9f6817a1e01674f383879eeaafc65a50825aa7554fedcf7fbe7affc43da16f7198761ca12b510d9980df5a5f41819a5415043ec91de55f1cb4d86e62e8e23ea0 SHA512 99026007af7fa00b82240c1f0e46a8d3db6c3434948aff7d0b01c2f99bccdd227a2a705bd83bce1ca2e47be13866d5d0a981c8b4ff8dec472612d6ee40f9ed2c
 DIST konversation-20.12.2.tar.xz 4222016 BLAKE2B 9f53e2f805959a2decbac907a8614f09f33edd2c0be666ef775893ec1101f1a243435314f10f2099c42631883fec07eea0ca28336b03860c6487e00d4606f78a SHA512 b9410c2a6b39f50734a1daa1903441c282fdbe128d0b0cb0cff3611ffb6bdd49a58d0f1b66dd3b9d6232110ed1ff82677ba14e2877d431602cad4a55248fc341
+DIST konversation-20.12.3.tar.xz 4242136 BLAKE2B 2483b34dde69a73029d15e8d626c77ebc9f91aaca0dc7b83f4b92629bbf773873de52bf8fd1ead3d862fbb496f2dcc3823320d983ea0c0f2c0ba8ac831ce379f SHA512 022854edac9e2b834e9c6795cd02e9d9fe5ab54f4d3facaff9f60cac680e1b6df12ef3ac3281a07d4ce732f491fe2b49f47fd467751c9b87549e02df3ef27bae
diff --git a/net-irc/konversation/konversation-20.12.3.ebuild b/net-irc/konversation/konversation-20.12.3.ebuild
new file mode 100644
index 000000000000..5e0ea6be4c39
--- /dev/null
+++ b/net-irc/konversation/konversation-20.12.3.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+KDE_RELEASE_SERVICE="true"
+KFMIN=5.74.0
+QTMIN=5.15.2
+inherit ecm kde.org
+
+DESCRIPTION="User friendly IRC Client"
+HOMEPAGE="https://konversation.kde.org https://apps.kde.org/en/konversation"
+
+LICENSE="GPL-2"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="+crypt"
+
+BDEPEND="sys-devel/gettext"
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kbookmarks-${KFMIN}:5
+	>=kde-frameworks/kcodecs-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kglobalaccel-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kidletime-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwallet-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=media-libs/phonon-4.11.0
+	crypt? ( >=app-crypt/qca-2.3.0:2 )
+"
+RDEPEND="${DEPEND}
+	>=dev-qt/qtsvg-${QTMIN}:5
+	crypt? ( >=app-crypt/qca-2.3.0:2[ssl] )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package crypt Qca-qt5)
+	)
+
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+
+	# Bug 616162
+	insinto /etc/xdg
+	doins "${FILESDIR}"/konversationrc
+}