net-libs/libqmi: bump

Package-Manager: Portage-2.3.3, Repoman-2.3.1

1 files changed, 45 insertions, 0 deletions

diff --git a/net-libs/libqmi/libqmi-1.18.0.ebuild b/net-libs/libqmi/libqmi-1.18.0.ebuild
new file mode 100644
index 000000000000..487726701682
--- /dev/null
+++ b/net-libs/libqmi/libqmi-1.18.0.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+inherit multilib
+if [[ ${PV} == "9999" ]] ; then
+	inherit git-r3 autotools
+	EGIT_REPO_URI="git://anongit.freedesktop.org/${PN}"
+else
+	KEYWORDS="~amd64 ~arm ~mips ~x86"
+	SRC_URI="https://www.freedesktop.org/software/${PN}/${P}.tar.xz"
+fi
+
+DESCRIPTION="Qualcomm MSM (Mobile Station Modem) Interface (QMI) modem protocol helper library"
+HOMEPAGE="https://cgit.freedesktop.org/libqmi/"
+
+LICENSE="LGPL-2"
+SLOT="0/5.1"	# soname of libqmi-glib.so
+IUSE="doc +mbim static-libs"
+
+RDEPEND=">=dev-libs/glib-2.32
+	mbim? ( >=net-libs/libmbim-1.14.0 )"
+DEPEND="${RDEPEND}
+	doc? ( dev-util/gtk-doc )
+	virtual/pkgconfig"
+[[ ${PV} == "9999" ]] && DEPEND+=" dev-util/gtk-doc" #469214
+
+src_prepare() {
+	default
+	[[ -e configure ]] || eautoreconf
+}
+
+src_configure() {
+	econf \
+		--disable-more-warnings \
+		$(use_enable mbim mbim-qmux) \
+		$(use_enable static{-libs,}) \
+		$(use_enable {,gtk-}doc)
+}
+
+src_install() {
+	default
+	use static-libs || rm -f "${ED}/usr/$(get_libdir)/${PN}-glib.la"
+}