net-misc/pulseaudio-dlna: python3 bump

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Matthew Thode <prometheanfire@gentoo.org>

3 files changed, 96 insertions, 20 deletions

diff --git a/net-misc/pulseaudio-dlna/Manifest b/net-misc/pulseaudio-dlna/Manifest
index 861b33a0ef7b..9da23b5d4e7f 100644
--- a/net-misc/pulseaudio-dlna/Manifest
+++ b/net-misc/pulseaudio-dlna/Manifest
@@ -1 +1,2 @@
+DIST b0db8137224f5a293329a60187365168304c3768.zip 744009 BLAKE2B d70584a3a188dffc2ace995318300f35aec235e1cb85d96d98f6c2eb758623c9cece8c5548a7369f88f291491e8edd013a4320ef3498a5efc73497168dfb933b SHA512 9533d890d3a7fca1a694abb94795a263549bbf60919f405c876281f23312065474a9444384c1d9c908b6d1282cb95ae891f345eba1b57b7bf2c136deeda5b5e7
 DIST pulseaudio-dlna-0.5.2.tar.gz 701412 BLAKE2B f31d2e5f9adb79fc2882b14582f2787f152675c6f2c97857edf93d6b28fe2d3cbc85badf427665dac44e7d37802365b287e42fd2f8c11bde7cec5267a2fddeb6 SHA512 298f61d643c35449fbb0001efa69a1792e41518953f58506703f3568902da4457d0f4f9e52b9641df26fc6f978670dd29a7f5d786b99339bd2a71f5fa59dd7db
diff --git a/net-misc/pulseaudio-dlna/pulseaudio-dlna-0.6.0_pre20200114.ebuild b/net-misc/pulseaudio-dlna/pulseaudio-dlna-0.6.0_pre20200114.ebuild
new file mode 100644
index 000000000000..2b1044ecf8fd
--- /dev/null
+++ b/net-misc/pulseaudio-dlna/pulseaudio-dlna-0.6.0_pre20200114.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_6 python3_7 )
+
+inherit distutils-r1
+
+DESCRIPTION="A lightweight DLNA/UPNP/Chromecast streaming server for PulseAudio"
+HOMEPAGE="https://github.com/masmu/pulseaudio-dlna"
+
+SRC_URI="https://github.com/masmu/pulseaudio-dlna/archive/b0db8137224f5a293329a60187365168304c3768.zip"
+KEYWORDS="~amd64 ~x86"
+S="${WORKDIR}/pulseaudio-dlna-b0db8137224f5a293329a60187365168304c3768"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE=""
+
+RDEPEND=">=dev-python/protobuf-python-2.5.0[${PYTHON_USEDEP}]
+	>=dev-python/docopt-0.6.1[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.2.1[${PYTHON_USEDEP}]
+	>=dev-python/setproctitle-1.1.10[${PYTHON_USEDEP}]
+	>=dev-python/notify2-0.3[${PYTHON_USEDEP}]
+	>=dev-python/psutil-5.4.7[${PYTHON_USEDEP}]
+	>=dev-python/chardet-3.0.4[${PYTHON_USEDEP}]
+	>=dev-python/pyroute2-0.3.5[${PYTHON_USEDEP}]
+	>=dev-python/netifaces-0.10.0[${PYTHON_USEDEP}]
+	>=dev-python/lxml-3[${PYTHON_USEDEP}]
+	>=dev-python/pychromecast-2.3.0[${PYTHON_USEDEP}]
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+	>=dev-python/dbus-python-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/zeroconf-0.17.4[${PYTHON_USEDEP}]
+	dev-python/pygobject[cairo,${PYTHON_USEDEP}]
+	gnome-base/librsvg[introspection]
+	x11-libs/gtk+:3[introspection]
+	|| (
+		|| (
+			media-video/ffmpeg[encode,faac,mp3,opus,vorbis]
+			media-video/ffmpeg[encode,fdk,mp3,opus,vorbis] )
+		( media-video/libav[encode,faac,mp3,opus,vorbis] )
+		( media-libs/faac
+			media-libs/flac
+			media-sound/lame
+			media-sound/opus-tools
+			media-sound/sox
+			media-sound/vorbis-tools )
+	)"
+
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	media-sound/pulseaudio"
+
+python_prepare_all() {
+	sed -i '/dbus-python/d' setup.py || die
+	sed -i '/notify2/d' setup.py || die
+	sed -i '/docopt/d' setup.py || die
+	sed -i '/pychromecast/d' setup.py || die
+	distutils-r1_python_prepare_all
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	insinto /usr/share/applications
+	doins "${FILESDIR}/${PN}.desktop"
+}
diff --git a/net-misc/pulseaudio-dlna/pulseaudio-dlna-9999.ebuild b/net-misc/pulseaudio-dlna/pulseaudio-dlna-9999.ebuild
index c62f80c399b7..09bcb5e33204 100644
--- a/net-misc/pulseaudio-dlna/pulseaudio-dlna-9999.ebuild
+++ b/net-misc/pulseaudio-dlna/pulseaudio-dlna-9999.ebuild
@@ -1,9 +1,8 @@
-# Copyright 1999-2017 Gentoo Foundation
+# Copyright 1999-2020 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
-PYTHON_COMPAT=( python2_7 )
-DISTUTILS_SINGLE_IMPL=1
+EAPI=7
+PYTHON_COMPAT=( python3_6 python3_7 )
 
 inherit distutils-r1
 
@@ -14,6 +13,7 @@ if [[ ${PV} == *9999 ]];then
 	inherit git-r3
 	SRC_URI=""
 	EGIT_REPO_URI="https://github.com/masmu/pulseaudio-dlna"
+	EGIT_BRANCH="python3"
 	KEYWORDS=""
 else
 	SRC_URI="https://github.com/masmu/pulseaudio-dlna/archive/v${PV}.tar.gz -> ${P}.tar.gz"
@@ -25,24 +25,26 @@ SLOT="0"
 IUSE=""
 
 RDEPEND=">=dev-python/protobuf-python-2.5.0[${PYTHON_USEDEP}]
-	>=dev-python/chardet-2.0.1[${PYTHON_USEDEP}]
-	>=dev-python/pyroute2-0.3.5[${PYTHON_USEDEP}]
 	>=dev-python/docopt-0.6.1[${PYTHON_USEDEP}]
-	>=dev-python/futures-2.1.6[${PYTHON_USEDEP}]
-	gnome-base/librsvg[introspection]
-	x11-libs/gtk+:3[introspection]
-	>=dev-python/lxml-3[${PYTHON_USEDEP}]
-	>=dev-python/netifaces-0.8[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.2.1[${PYTHON_USEDEP}]
+	>=dev-python/setproctitle-1.1.10[${PYTHON_USEDEP}]
 	>=dev-python/notify2-0.3[${PYTHON_USEDEP}]
-	>=dev-python/psutil-1.2.1[${PYTHON_USEDEP}]
-	dev-python/pycairo[${PYTHON_USEDEP}]
+	>=dev-python/psutil-5.4.7[${PYTHON_USEDEP}]
+	>=dev-python/chardet-3.0.4[${PYTHON_USEDEP}]
+	>=dev-python/pyroute2-0.3.5[${PYTHON_USEDEP}]
+	>=dev-python/netifaces-0.10.0[${PYTHON_USEDEP}]
+	>=dev-python/lxml-3[${PYTHON_USEDEP}]
+	>=dev-python/pychromecast-2.3.0[${PYTHON_USEDEP}]
 	dev-python/pygobject:3[${PYTHON_USEDEP}]
-	>=dev-python/requests-2.2.1[${PYTHON_USEDEP}]
-	>=dev-python/setproctitle-1.0.1[${PYTHON_USEDEP}]
+	>=dev-python/dbus-python-1.0.0[${PYTHON_USEDEP}]
 	>=dev-python/zeroconf-0.17.4[${PYTHON_USEDEP}]
+	dev-python/pygobject[cairo,${PYTHON_USEDEP}]
+	gnome-base/librsvg[introspection]
+	x11-libs/gtk+:3[introspection]
 	|| (
-		|| ( media-video/ffmpeg[encode,faac,mp3,opus,vorbis]
-		     media-video/ffmpeg[encode,fdk,mp3,opus,vorbis] )
+		|| (
+			media-video/ffmpeg[encode,faac,mp3,opus,vorbis]
+			media-video/ffmpeg[encode,fdk,mp3,opus,vorbis] )
 		( media-video/libav[encode,faac,mp3,opus,vorbis] )
 		( media-libs/faac
 			media-libs/flac
@@ -50,14 +52,20 @@ RDEPEND=">=dev-python/protobuf-python-2.5.0[${PYTHON_USEDEP}]
 			media-sound/opus-tools
 			media-sound/sox
 			media-sound/vorbis-tools )
-	)
-	virtual/python-futures[${PYTHON_USEDEP}]"
+	)"
 
 DEPEND="${RDEPEND}
-	dev-python/dbus-python[${PYTHON_USEDEP}]
 	dev-python/setuptools[${PYTHON_USEDEP}]
 	media-sound/pulseaudio"
 
+python_prepare_all() {
+	sed -i '/dbus-python/d' setup.py || die
+	sed -i '/notify2/d' setup.py || die
+	sed -i '/docopt/d' setup.py || die
+	sed -i '/pychromecast/d' setup.py || die
+	distutils-r1_python_prepare_all
+}
+
 src_install() {
 	distutils-r1_src_install