net-wireless/aircrack-ng: migrate to hwdata

Signed-off-by: Mike Gilbert <floppym@gentoo.org>

3 files changed, 148 insertions, 1 deletions

diff --git a/net-wireless/aircrack-ng/aircrack-ng-1.6_p20200722-r1.ebuild b/net-wireless/aircrack-ng/aircrack-ng-1.6_p20200722-r1.ebuild
new file mode 100644
index 000000000000..3e29615b279a
--- /dev/null
+++ b/net-wireless/aircrack-ng/aircrack-ng-1.6_p20200722-r1.ebuild
@@ -0,0 +1,121 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+DISTUTILS_OPTIONAL=1
+
+inherit toolchain-funcs distutils-r1 flag-o-matic autotools
+
+DESCRIPTION="WLAN tools for breaking 802.11 WEP/WPA keys"
+HOMEPAGE="http://www.aircrack-ng.org"
+
+if [[ ${PV} == "9999" ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/aircrack-ng/aircrack-ng.git"
+else
+	#SRC_URI="https://download.aircrack-ng.org/${P}.tar.gz"
+	COMMIT="5a02ac4818b30d2e87b3e18e497a5f9e5319394f"
+	SRC_URI="https://github.com/aircrack-ng/aircrack-ng/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/${PN}-${COMMIT}"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+
+IUSE="+airdrop-ng +airgraph-ng kernel_linux kernel_FreeBSD +netlink +pcre +sqlite +experimental"
+
+DEPEND="net-libs/libpcap
+	sys-apps/hwloc:0=
+	dev-libs/openssl:0=
+	netlink? ( dev-libs/libnl:3 )
+	pcre? ( dev-libs/libpcre )
+	airdrop-ng? ( ${PYTHON_DEPS} )
+	airgraph-ng? ( ${PYTHON_DEPS} )
+	experimental? ( sys-libs/zlib )
+	sqlite? ( >=dev-db/sqlite-3.4 )"
+RDEPEND="${DEPEND}
+	kernel_linux? (
+		net-wireless/iw
+		net-wireless/wireless-tools
+		sys-apps/ethtool
+		sys-apps/usbutils
+		sys-apps/pciutils )
+	sys-apps/hwdata
+	airdrop-ng? ( net-wireless/lorcon[python,${PYTHON_USEDEP}] )"
+
+REQUIRED_USE="
+	airdrop-ng? ( ${PYTHON_REQUIRED_USE} )
+	airgraph-ng? ( ${PYTHON_REQUIRED_USE} )"
+
+src_prepare() {
+	local PATCHES=(
+		"${FILESDIR}/aircrack-ng-1.6-hwdata.patch"
+	)
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		STATIC_LIBDIR_NAME="$(get_libdir)" \
+		--disable-asan \
+		--enable-shared \
+		--disable-static \
+		--without-opt \
+		$(use_enable netlink libnl) \
+		$(use_with experimental) \
+		$(use_with sqlite sqlite3)
+}
+
+src_compile() {
+	if [[ $($(tc-getCC) --version) == clang* ]] ; then
+		#https://bugs.gentoo.org/show_bug.cgi?id=472890
+		filter-flags -frecord-gcc-switches
+	fi
+
+	default
+
+	if use airgraph-ng; then
+		cd "${S}/scripts/airgraph-ng"
+		distutils-r1_src_compile
+	fi
+	if use airdrop-ng; then
+		cd "${S}/scripts/airdrop-ng"
+		distutils-r1_src_compile
+	fi
+}
+
+src_install() {
+	default
+
+	if use airgraph-ng; then
+		cd "${S}/scripts/airgraph-ng"
+		distutils-r1_src_install
+	fi
+	if use airdrop-ng; then
+		cd "${S}/scripts/airdrop-ng"
+		distutils-r1_src_install
+	fi
+
+	# we don't need aircrack-ng's oui updater, we have our own
+	rm "${ED}"/usr/sbin/airodump-ng-oui-update
+	find "${D}" -xtype f -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	# Message is (c) FreeBSD
+	# http://www.freebsd.org/cgi/cvsweb.cgi/ports/net-mgmt/aircrack-ng/files/pkg-message.in?rev=1.5
+	if use kernel_FreeBSD ; then
+		einfo "Contrary to Linux, it is not necessary to use airmon-ng to enable the monitor"
+		einfo "mode of your wireless card.  So do not care about what the manpages say about"
+		einfo "airmon-ng, airodump-ng sets monitor mode automatically."
+		echo
+		einfo "To return from monitor mode, issue the following command:"
+		einfo "    ifconfig \${INTERFACE} -mediaopt monitor"
+		einfo
+		einfo "For aireplay-ng you need FreeBSD >= 7.0."
+	fi
+}
diff --git a/net-wireless/aircrack-ng/aircrack-ng-9999.ebuild b/net-wireless/aircrack-ng/aircrack-ng-9999.ebuild
index ea254ead117a..e7aadf29d9b5 100644
--- a/net-wireless/aircrack-ng/aircrack-ng-9999.ebuild
+++ b/net-wireless/aircrack-ng/aircrack-ng-9999.ebuild
@@ -41,7 +41,7 @@ RDEPEND="${DEPEND}
 		sys-apps/ethtool
 		sys-apps/usbutils
 		sys-apps/pciutils )
-	sys-apps/hwids
+	sys-apps/hwdata
 	airdrop-ng? ( net-wireless/lorcon[python,${PYTHON_USEDEP}] )"
 
 REQUIRED_USE="
diff --git a/net-wireless/aircrack-ng/files/aircrack-ng-1.6-hwdata.patch b/net-wireless/aircrack-ng/files/aircrack-ng-1.6-hwdata.patch
new file mode 100644
index 000000000000..bedc14f3ffc1
--- /dev/null
+++ b/net-wireless/aircrack-ng/files/aircrack-ng-1.6-hwdata.patch
@@ -0,0 +1,26 @@
+From f493d0ba1d2cd6c2fdd3c80fe20908c5a6a0001a Mon Sep 17 00:00:00 2001
+From: Mike Gilbert <floppym@gentoo.org>
+Date: Thu, 25 Nov 2021 12:28:07 -0500
+Subject: [PATCH] airodump-ng: look for oui.txt in /usr/share/hwdata
+
+This location is used by the hwdata package on various distros.
+
+https://github.com/vcrhonek/hwdata
+
+Signed-off-by: Mike Gilbert <floppym@gentoo.org>
+---
+ src/airodump-ng/airodump-ng.c | 1 +
+ 1 file changed, 1 insertion(+)
+
+diff --git a/src/airodump-ng/airodump-ng.c b/src/airodump-ng/airodump-ng.c
+index 63013450d..23171854e 100644
+--- a/src/airodump-ng/airodump-ng.c
++++ b/src/airodump-ng/airodump-ng.c
+@@ -102,6 +102,7 @@ static const char * OUI_PATHS[]
+ 	   "/usr/share/aircrack-ng/airodump-ng-oui.txt",
+ 	   "/var/lib/misc/oui.txt",
+ 	   "/usr/share/misc/oui.txt",
++	   "/usr/share/hwdata/oui.txt",
+ 	   "/var/lib/ieee-data/oui.txt",
+ 	   "/usr/share/ieee-data/oui.txt",
+ 	   "/etc/manuf/oui.txt",