sci-libs/blis: bump to 0.6.0, getting rid of a patch.

Closes: https://github.com/gentoo/gentoo/pull/12358
Signed-off-by: Mo Zhou <cdluminate@gmail.com>
Signed-off-by: Benda Xu <heroxbd@gentoo.org>

4 files changed, 133 insertions, 0 deletions

diff --git a/sci-libs/blis/Manifest b/sci-libs/blis/Manifest
index 7d42eadf47b8..a251246c916c 100644
--- a/sci-libs/blis/Manifest
+++ b/sci-libs/blis/Manifest
@@ -1 +1,2 @@
 DIST blis-0.5.2.tar.gz 3502383 BLAKE2B b09fda20711086c8bde0d4efc3f3c9b0f6072e1ddb8bd2846465877f0353cced27548abe1239b6a042fe655e85e4b7b3c960322e39b2c733866b8e17777718bd SHA512 4f91a7834ef0ed39544dd21856814467416a222240050cca323917b0fc61b9201ae4dbd109aa687cdecb27ddee5d6bf4510ef023e1c1dc73599faef0482d3d04
+DIST blis-0.6.0.tar.gz 5107257 BLAKE2B cd589ad1216486e8bb0cf574cc096c1e1f2bb9587b182c2bcff44db322468d9f027323c0bf2d22ea0fabb1902dc047d2bf62253ef1c2797fc3de9ba53d7fc34a SHA512 74e9da5146f7986cbd11651d7cd0837562a1603c667b9e6d3f79b5057443de657b60d7463cb2d64daf3eff7d33fc05a64e6d8eb807f4cabe0c3121517924a206
diff --git a/sci-libs/blis/blis-0.6.0.ebuild b/sci-libs/blis/blis-0.6.0.ebuild
new file mode 100644
index 000000000000..fd8ccbe5c4ca
--- /dev/null
+++ b/sci-libs/blis/blis-0.6.0.ebuild
@@ -0,0 +1,106 @@
+# Copyright 2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit eutils
+
+DESCRIPTION="BLAS-like Library Instantiation Software Framework"
+HOMEPAGE="https://github.com/flame/blis"
+SRC_URI="https://github.com/flame/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+IUSE="openmp pthread serial static-libs eselect-ldso doc 64bit-index"
+REQUIRED_USE="?? ( openmp pthread serial ) ?? ( eselect-ldso 64bit-index )"
+
+RDEPEND="eselect-ldso? ( !app-eselect/eselect-cblas
+				   >=app-eselect/eselect-blas-0.2 )"
+
+DEPEND="${RDEPEND}
+	dev-lang/python
+"
+
+PATCHES=(
+	"${FILESDIR}/${P}-rpath.patch"
+	"${FILESDIR}/${P}-blas-provider.patch"
+)
+
+src_configure () {
+	local BLIS_FLAGS=()
+	local confname
+	# determine flags
+	if use openmp; then
+		BLIS_FLAGS+=( -t openmp )
+	elif use pthread; then
+		BLIS_FLAGS+=( -t pthreads )
+	else
+		BLIS_FLAGS+=( -t no )
+	fi
+	use 64bit-index && BLIS_FLAGS+=( -b 64 -i 64 )
+	# determine config name
+	case "${ARCH}" in
+		"x86" | "amd64")
+			confname=auto ;;
+		"ppc64")
+			confname=generic ;;
+		*)
+			confname=generic ;;
+	esac
+	# This is not an autotools configure file. We don't use econf here.
+	./configure \
+		--enable-verbose-make \
+		--prefix="${BROOT}"/usr \
+		--libdir="${BROOT}"/usr/$(get_libdir) \
+		$(use_enable static-libs static) \
+		--enable-blas \
+		--enable-cblas \
+		${BLIS_FLAGS[@]} \
+		--enable-shared \
+		$confname || die
+}
+
+src_compile() {
+	DEB_LIBBLAS=libblas.so.3 DEB_LIBCBLAS=libcblas.so.3 \
+		LDS_BLAS="${FILESDIR}"/blas.lds LDS_CBLAS="${FILESDIR}"/cblas.lds \
+		default
+}
+
+src_test () {
+	emake check
+}
+
+src_install () {
+	default
+	use doc && dodoc README.md docs/*.md
+
+	if use eselect-ldso; then
+		dodir /usr/$(get_libdir)/blas/blis
+		insinto /usr/$(get_libdir)/blas/blis
+		doins lib/*/lib{c,}blas.so.3
+		dosym libblas.so.3 usr/$(get_libdir)/blas/blis/libblas.so
+		dosym libcblas.so.3 usr/$(get_libdir)/blas/blis/libcblas.so
+	fi
+}
+
+pkg_postinst() {
+	use eselect-ldso || return
+
+	local libdir=$(get_libdir) me="blis"
+
+	# check blas
+	eselect blas add ${libdir} "${EROOT}"/usr/${libdir}/blas/${me} ${me}
+	local current_blas=$(eselect blas show ${libdir})
+	if [[ ${current_blas} == blis || -z ${current_blas} ]]; then
+		eselect blas set ${libdir} ${me}
+		elog "Current eselect: BLAS/CBLAS ($libdir) -> [${current_blas}]."
+	else
+		elog "Current eselect: BLAS/CBLAS ($libdir) -> [${current_blas}]."
+		elog "To use blas [${me}] implementation, you have to issue (as root):"
+		elog "\t eselect blas set ${libdir} ${me}"
+	fi
+}
+
+pkg_postrm() {
+	use eselect-ldso && eselect blas validate
+}
diff --git a/sci-libs/blis/files/blis-0.6.0-blas-provider.patch b/sci-libs/blis/files/blis-0.6.0-blas-provider.patch
new file mode 100644
index 000000000000..5999f847929c
--- /dev/null
+++ b/sci-libs/blis/files/blis-0.6.0-blas-provider.patch
@@ -0,0 +1,13 @@
+diff --git a/Makefile b/Makefile
+index 2d31fee..7008682 100644
+--- a/Makefile
++++ b/Makefile
+@@ -659,6 +659,8 @@ else
+ 	@$(LINKER) $(SOFLAGS) -o $(LIBBLIS_SO_OUTPUT_NAME) $? $(LDFLAGS)
+ endif
+ endif
++	$(LINKER) $(SOFLAGS) -o $(BASE_LIB_PATH)/$(DEB_LIBBLAS) $? $(LDFLAGS) -Wl,--soname,$(DEB_LIBBLAS) -Wl,--version-script=$(LDS_BLAS)
++	$(LINKER) $(SOFLAGS) -o $(BASE_LIB_PATH)/$(DEB_LIBCBLAS) $? $(LDFLAGS) -Wl,--soname,$(DEB_LIBCBLAS) -Wl,--version-script=$(LDS_CBLAS)
+ 
+ # Local symlink for shared library.
+ # NOTE: We use a '.loc' suffix to avoid filename collisions in case this
diff --git a/sci-libs/blis/files/blis-0.6.0-rpath.patch b/sci-libs/blis/files/blis-0.6.0-rpath.patch
new file mode 100644
index 000000000000..a8b5a46870d1
--- /dev/null
+++ b/sci-libs/blis/files/blis-0.6.0-rpath.patch
@@ -0,0 +1,13 @@
+diff --git a/common.mk b/common.mk
+index ef0acfb..e1ce31d 100644
+--- a/common.mk
++++ b/common.mk
+@@ -527,7 +527,7 @@ LIBBLIS_L      := $(LIBBLIS_SO)
+ LIBBLIS_LINK   := $(LIBBLIS_SO_PATH)
+ ifeq ($(IS_WIN),no)
+ # For Linux and OS X: set rpath property of shared object.
+-LDFLAGS        += -Wl,-rpath,$(BASE_LIB_PATH)
++#LDFLAGS        += -Wl,-rpath,$(BASE_LIB_PATH)
+ endif
+ endif
+ endif