sys-apps/dbus-broker: bump to 21

Package-Manager: Portage-2.3.71, Repoman-2.3.16_p24
Signed-off-by: Mike Gilbert <floppym@gentoo.org>

1 files changed, 76 insertions, 0 deletions

diff --git a/sys-apps/dbus-broker/dbus-broker-21.ebuild b/sys-apps/dbus-broker/dbus-broker-21.ebuild
new file mode 100644
index 000000000000..20cbb6de4c14
--- /dev/null
+++ b/sys-apps/dbus-broker/dbus-broker-21.ebuild
@@ -0,0 +1,76 @@
+# Copyright 2017-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit meson
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/bus1/dbus-broker.git"
+else
+	KEYWORDS="~amd64"
+	SRC_URI="https://github.com/bus1/dbus-broker/archive/v${PV}/${P}.tar.gz"
+	declare -A SUBPROJECTS=(
+		[c-dvar]=7c0833f9cae446163077b204b2296287bbee7c67
+		[c-ini]=847c55f5b3d33baa47af9a1286175d58b34f91d5
+		[c-list]=2e4b605c6217cd3c8a1ef773f82f5cc329ba650d
+		[c-rbtree]=b46392d25de7a7bab67d48ef18bf8350b429cff5
+		[c-shquote]=34e1e25299fb82ab9fd0c8bfd8a66010ead1497b
+		[c-stdaux]=11930d259212605a15430523472ef54e0c7654ee
+		[c-utf8]=34f5df0f4b28fc7ea6747680a432e666047082e4
+	)
+	for sp in "${!SUBPROJECTS[@]}"; do
+		commit=${SUBPROJECTS[${sp}]}
+		SRC_URI+=" https://github.com/c-util/${sp}/archive/${commit}/${sp}-${commit}.tar.gz"
+	done
+	unset sp commit
+fi
+
+DESCRIPTION="Linux D-Bus Message Broker"
+HOMEPAGE="https://github.com/bus1/dbus-broker/wiki"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="audit doc +launcher selinux"
+
+DEPEND="
+	audit? (
+		>=sys-process/audit-2.7
+		>=sys-libs/libcap-ng-0.6
+	)
+	launcher? (
+		>=dev-libs/expat-2.2
+		>=sys-apps/systemd-230:0=
+	)
+	selinux? ( sys-libs/libselinux )
+"
+RDEPEND="${DEPEND}
+	launcher? ( sys-apps/dbus )"
+BDEPEND="
+	doc? ( dev-python/docutils )
+	dev-python/docutils
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	if [[ ${PV} != 9999 ]]; then
+		local sp commit
+		for sp in "${!SUBPROJECTS[@]}"; do
+			commit=${SUBPROJECTS[${sp}]}
+			rmdir "subprojects/${sp}" || die
+			mv "${WORKDIR}/${sp}-${commit}" "subprojects/${sp}" || die
+		done
+	fi
+	default
+}
+
+src_configure() {
+	local emesonargs=(
+		-Daudit=$(usex audit true false)
+		-Ddocs=$(usex doc true false)
+		-Dlauncher=$(usex launcher true false)
+		-Dselinux=$(usex selinux true false)
+	)
+	meson_src_configure
+}