sys-kernel/gentoo-kernel-bin: bump to 5.10.47-r1 for arm64

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 115 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 50e49e3353a2..a3c557f1322c 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -58,6 +58,7 @@ DIST gentoo-kernel-5.10.46-1.amd64.xpak 65480369 BLAKE2B 69fef95b1daaad661467171
 DIST gentoo-kernel-5.10.46-1.arm64.xpak 59246438 BLAKE2B d263f86f320e8206f71eb1a80cc79b89aaa96efe722343e041023d2d0950e69ba3c6020cf2c984ff4e93c816cfa843e253e284caafb10fbf1b08d3bbe1413a45 SHA512 df4fb4cdc173135835508ef13f363406c9f9757eb1e67360f19e8179d067c21367ef783443086c348b2101e12fd1619292cf256ca90401c955dbd95d7056dc77
 DIST gentoo-kernel-5.10.46-1.x86.xpak 57216120 BLAKE2B fe702f3ff06d1394887c1c4ef91ea6e10582b1b33e1b8d821b07feec6f9a54220b0d1e878e4b63961c817f574c727e55ac0b9db459fb3d3ad2c81e7a838e077c SHA512 75d6cad82e5ef99cac80acca448ffaba9f03e2985fa78d4ebfd8c39c694ddf7b803a3720aab731987094428a9afc195860f3013c0e33892bdafcbee6f5455c61
 DIST gentoo-kernel-5.10.47-1.amd64.xpak 65480161 BLAKE2B 60863347327dbb67ba16881c01244ab01f7246267989018373a85c5fb479521f4c70574274a5b7caf98dd78f9601e80a887cc115e87f8004bba292d438879970 SHA512 a73474d584215180daf7c2aa9bd985b29234bcc319b9b8a4691467993cabd8c532efa611bfc3b13b323d5635cda556b57e704c11d8a43b13a3efaba8cb84fe64
+DIST gentoo-kernel-5.10.47-1.arm64.xpak 59021827 BLAKE2B 7a322a113ffd53ec9c8ea8fbe06b9d4a4cc43b2519c3f33ea4b875c53192e58cbac345c21904f9f4a718576bf59d5062e7a0b46cea6c51453565afe8e01fdd55 SHA512 c7fb021069e49177605eca80b9b5ece948394dacc0b2fb280bfb834606db5d4e05f7516f20539c5a5f5075fe7ad216b8b5cef7d6e829099ca80a0b2c03ed21fb
 DIST gentoo-kernel-5.10.47-1.x86.xpak 57221591 BLAKE2B e069b66b20c0c9fe3ab35cea65dbe797b1a5a9b2c80b11d5e49113ace7d9df5eff6a5b1aafcd7a65f5df96d21796fa89ea75b825cfef61058a5f5af13f6e5c7e SHA512 14982da4f9fd7ac365641a5a7f6eda290691bf4c36d67a2f4353d1e16c0bd3e64e3c9cf47c517c295c229cacf70c157614808054b3b96363f128c71d6fb8abed
 DIST gentoo-kernel-5.10.48-1.amd64.xpak 65536136 BLAKE2B be9827d86c0fe12b750aa5ea9236287a80612774e04e2226828d1224428133fcea711690b0680e9831235d6b38a6c96cdea5b0047b54291d27178d3d562e18f7 SHA512 9d029ac037d5ec184c12bc9a7f4b6383205185dfa88a9624c5b207087c4094a020f9c972ddf233ec2a0335aef9ca65feebb92b9b7a6241d04fe6f098e251297a
 DIST gentoo-kernel-5.10.48-1.x86.xpak 57223594 BLAKE2B cdaf9e1f4d49cfb1e772a5c5ad92bfcdca846a16a540032136845c1fc7256c6df405e2d1613377dc5046209a750bfb9b6d543203d604853b2f2d7dfb6e786c5e SHA512 3c1e1895a89cff6f03fda61613c8bc1c62cce4c98992e354b9572965728ece2e7556121edc725a942a23b9eccdc52d6282ef3bd929cb79052ce2ff495a849db4
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.47-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.47-r1.ebuild
new file mode 100644
index 000000000000..b63276300c50
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.47-r1.ebuild
@@ -0,0 +1,114 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 3 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)
+"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}