sys-kernel/gentoo-kernel-bin: bump to 5.10.40 for arm64

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 115 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 9d193b573a0c..9e628733a39b 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -30,6 +30,7 @@ DIST gentoo-kernel-5.10.39-1.amd64.xpak 65488886 BLAKE2B 88f563aeab27d6ad9deea14
 DIST gentoo-kernel-5.10.39-1.arm64.xpak 59266825 BLAKE2B 50279064ef8eb44dbcf16478eaf2596bd33b8222f30e18aee220aee470ceed8439fddcdf2d27fe2d78967f3b65d42bb48dfb2e0cf5dc009508fa18ee2011f0c5 SHA512 cc3fe299bd136e7b5de28fcc4607e4a50491b9792d685e81021865eb4931628cda3906a15dd1f0dd82ff242f12f55d9395f4f75356d10ec87c7b4b41956c6431
 DIST gentoo-kernel-5.10.39-1.x86.xpak 57235316 BLAKE2B 6061e3cafc53ea2cb6a0053aeec0b3f5190554984fa0448269c515580492c4af71b5203a34a7e8c613e3560b897e718bf418459507ddb00fb02baa53735f27ec SHA512 d08a7d06cd3fef9e72850412300fe97720d9d107847e9bff2b0d42a5ef3d8c840a7b9274d69307c93df8f856ccc1fc86a2edb712921f26bab7a77563831ce1e7
 DIST gentoo-kernel-5.10.40-1.amd64.xpak 65506415 BLAKE2B 91f5c3f13350c922d40740c4c1aa16938aaef9249beeff2615ce4ab4426d371482edca90160f4729e4bbd97c4d373a886e8ba701e4a7d8a40050014b66d68deb SHA512 91a96bb4a0d4f44868df55ead4b997b8735da51a1f37ad9054eac15e9f552b7505dd155b1bd01f698ec26b9ebbe0cfd6b98e93e1a6c9167d7ec15133de36c25f
+DIST gentoo-kernel-5.10.40-1.arm64.xpak 59237288 BLAKE2B 21e19596314712a4d535d188744a9b7e7f3b155f767ff4c85dd9aed3dd46867f52bc649b8ea4dd76355b5a462d297d4c20757707ed3a0bca136cb56dd1caa699 SHA512 b352c943d33430b5e04c63ff0d33e80aac2171d6e1048f8a1029730e0a8b08bd7ebaf40d0afe4174b8600cd8c47322304e49c2fb72ab5a19b53d3fdb34ffbcfd
 DIST gentoo-kernel-5.10.40-1.x86.xpak 57236415 BLAKE2B 803f67facaaa6f162f34290c79bd0a33c6121221da09b9f09083df5cd6fbf3aee8517926fd80261352194ebb4b977c27d06b77a06ff01ef0fa7f17573260e186 SHA512 c78f1388bc34658a2c2e261085752a581110bd2650d06e6bef4ee3a4e62fd323c8e33ae74b6a795700ef2e205d872e914ee4358c0d1bfac43f7c209fd305c103
 DIST gentoo-kernel-5.11.22-1.amd64.xpak 65882786 BLAKE2B aa98de82c4f47a586474f6f888a12fa3fb4605bd3dae576a36a9edfd10b669cb586d975dd6dfd4fac0ca3906e56a14250effb44b54ea6646898b12ddeeb6ae28 SHA512 1cd5f40f7ae0500158d05e3da14788a407faef9c471001fa5cb403e6cbbd062130645166cab28f3ad79cb6318dd0fb5961a515952a91de35f34b44483931c5a2
 DIST gentoo-kernel-5.11.22-1.arm64.xpak 59725454 BLAKE2B bffe7733b1ab766ab7afae20c77696ab36bed989dae7fef60e6eba752da8f918240e0d28fdce01d5813775c4013df80ba495e6ed7163838bde2896ffce96fb06 SHA512 8b1e4b0f6ca7294a457574f23557df1cc99dc6be41f3a36f6a871cb8a21d52f0556279afe400301bbdf715d4e07134da845c37318a1e6df9e14e379cf4252f68
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.40-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.40-r1.ebuild
new file mode 100644
index 000000000000..8198cf5ace09
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.40-r1.ebuild
@@ -0,0 +1,114 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 3 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)
+"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}