www-apps/nikola: Version bump to 8.2.2

Closes: https://bugs.gentoo.org/836691
Closes: https://bugs.gentoo.org/843680
Signed-off-by: Ulrich Müller <ulm@gentoo.org>

2 files changed, 61 insertions, 0 deletions

diff --git a/www-apps/nikola/Manifest b/www-apps/nikola/Manifest
index d5a48bc3ba3b..bb7f0c83af11 100644
--- a/www-apps/nikola/Manifest
+++ b/www-apps/nikola/Manifest
@@ -1 +1,2 @@
 DIST Nikola-8.1.3.tar.gz 4340545 BLAKE2B 535870b7cd147169b511166186ac200ab9d31d976c58363e42235e07ea8ba68e01738d378190663864e6a8605986771500569004e7a73ea043ae8982be09afe1 SHA512 7b6a8391d023a339125392082cc3d2ea2a2fe25b8938bd82b8c9efe0cbb3e8b83537f1bd00d97a648e3fc2b096e673702026fa3942ab9c97e76bf21b5afefe16
+DIST Nikola-8.2.2.tar.gz 5483145 BLAKE2B 78950e97016b7a87d41739684de102c548a5dfecfe9c1239a94c757a4d7d00f5d77bf679b6ed1a853aa46e1fcb78c27e7c2276e7aafeb874c0e21c1ae9f1cbb2 SHA512 f2bf38c81c2e01f6d6cb6a24d9b9ea95f047e9bd9987437df61cf1cb10c39c5f9259e8baa4c64dc24e4f69dc3b3e35e3553dced7d42c840645e024d6c21eb9ae
diff --git a/www-apps/nikola/nikola-8.2.2.ebuild b/www-apps/nikola/nikola-8.2.2.ebuild
new file mode 100644
index 000000000000..6aa7aff76bbf
--- /dev/null
+++ b/www-apps/nikola/nikola-8.2.2.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8,9} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit distutils-r1
+
+MY_PN="Nikola"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="A static website and blog generator"
+HOMEPAGE="https://getnikola.com/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="MIT Apache-2.0 CC0-1.0 public-domain"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv"
+IUSE="assets charts hyphenation ipython jinja server watchdog webmedia"
+REQUIRED_USE="server? ( watchdog )"
+RESTRICT="test" # needs coveralls
+
+DEPEND=">=dev-python/docutils-0.13[${PYTHON_USEDEP}]" # needs rst2man to build manpage
+RDEPEND="${DEPEND}
+	>=dev-python/Babel-2.6.0[${PYTHON_USEDEP}]
+	>=dev-python/blinker-1.3[${PYTHON_USEDEP}]
+	>=dev-python/doit-0.32[${PYTHON_USEDEP}]
+	>=dev-python/lxml-3.3.5[${PYTHON_USEDEP}]
+	>=dev-python/mako-1.0[${PYTHON_USEDEP}]
+	>=dev-python/markdown-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/natsort-3.5.2[${PYTHON_USEDEP}]
+	>=dev-python/piexif-1.0.3[${PYTHON_USEDEP}]
+	>=dev-python/pygments-1.6[${PYTHON_USEDEP}]
+	>=dev-python/PyRSS2Gen-1.1[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.6.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/unidecode-0.04.16[${PYTHON_USEDEP}]
+	>=dev-python/yapsy-1.11.223[${PYTHON_USEDEP}]
+	dev-python/pillow[jpeg,${PYTHON_USEDEP}]
+	dev-python/cloudpickle[${PYTHON_USEDEP}]
+	assets? ( >=dev-python/webassets-0.10.1[${PYTHON_USEDEP}] )
+	charts? ( >=dev-python/pygal-2.0.1[${PYTHON_USEDEP}] )
+	hyphenation? ( >=dev-python/pyphen-0.9.1[${PYTHON_USEDEP}] )
+	ipython? ( >=dev-python/ipython-2.0.0[notebook,${PYTHON_USEDEP}] )
+	jinja? ( >=dev-python/jinja-2.7.2[${PYTHON_USEDEP}] )
+	server? ( dev-python/aiohttp[${PYTHON_USEDEP}] )
+	watchdog? ( >=dev-python/watchdog-0.8.3[${PYTHON_USEDEP}] )
+	webmedia? ( >=dev-python/micawber-0.3.0[${PYTHON_USEDEP}] )"
+
+src_install() {
+	distutils-r1_src_install
+
+	# hackish way to remove docs that ended up in the wrong place
+	rm -r "${ED}/usr/share/doc/${PN}" || die
+
+	dodoc AUTHORS.txt CHANGES.txt README.rst docs/*.rst
+	gunzip "${ED}/usr/share/man/man1/${PN}.1.gz" || die
+}