x11-misc/fbpanel: Fix image permissions

Package-Manager: Portage-2.3.59, Repoman-2.3.12

Fixes: https://bugs.gentoo.org/677390
Signed-off-by: Jeroen Roovers <jer@gentoo.org>

2 files changed, 68 insertions, 0 deletions

diff --git a/x11-misc/fbpanel/fbpanel-7.0-r1.ebuild b/x11-misc/fbpanel/fbpanel-7.0-r1.ebuild
new file mode 100644
index 000000000000..4fa276907256
--- /dev/null
+++ b/x11-misc/fbpanel/fbpanel-7.0-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python2_7 )
+
+inherit python-any-r1 toolchain-funcs
+
+DESCRIPTION="light-weight X11 desktop panel"
+HOMEPAGE="https://aanatoly.github.io/fbpanel/"
+SRC_URI="${HOMEPAGE}archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~mips ~ppc ~ppc64 ~x86"
+IUSE="alsa"
+
+RDEPEND="
+	dev-libs/glib:2
+	alsa? ( media-libs/alsa-lib )
+	x11-libs/gdk-pixbuf:2[X]
+	x11-libs/gtk+:2
+	x11-libs/libX11
+"
+DEPEND="
+	${RDEPEND}
+	${PYTHON_DEPS}
+	virtual/pkgconfig
+	x11-base/xorg-proto
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-6.1-underlinking.patch
+	"${FILESDIR}"/${PN}-7.0-clang.patch
+	"${FILESDIR}"/${PN}-7.0-images.patch
+	"${FILESDIR}"/${PN}-7.0-shebangs.patch
+)
+
+src_configure() {
+	tc-export CC
+	# not autotools based
+	local myconfigure=(
+		./configure V=1
+		--mandir="${EPREFIX}"/usr/share/man/man1
+		--datadir="${EPREFIX}"/usr/share/${PN}
+		--prefix="${EPREFIX}"/usr
+		--libdir="${EPREFIX}"/usr/$(get_libdir)/${PN}
+		$(usex alsa --sound --no-sound)
+	)
+	echo ${myconfigure[@]} || die
+	${myconfigure[@]} || die
+}
+
+pkg_postinst() {
+	elog "For the volume plugin to work, you need to configure your kernel"
+	elog "with CONFIG_SND_MIXER_OSS or CONFIG_SOUND_PRIME or some other means"
+	elog "that provide the /dev/mixer device node."
+}
diff --git a/x11-misc/fbpanel/files/fbpanel-7.0-images.patch b/x11-misc/fbpanel/files/fbpanel-7.0-images.patch
new file mode 100644
index 000000000000..c1b9faf6304b
--- /dev/null
+++ b/x11-misc/fbpanel/files/fbpanel-7.0-images.patch
@@ -0,0 +1,10 @@
+--- a/data/images/Makefile
++++ b/data/images/Makefile
+@@ -31,6 +31,6 @@
+ 
+ install :
+ 	$Qinstall -d $(DESTDIR)$(DATADIR)/images
+-	$Qinstall $(IMAGES) $(DESTDIR)$(DATADIR)/images
++	$Qinstall -m 0644 $(IMAGES) $(DESTDIR)$(DATADIR)/images
+ 
+ include $(TOPDIR)/.config/rules.mk