1 files changed, 48 insertions, 0 deletions
diff --git a/app-emacs/ebib/ebib-2.49.1.ebuild b/app-emacs/ebib/ebib-2.49.1.ebuild
new file mode 100644
index 000000000000..68bce79a5e88
--- /dev/null
+++ b/app-emacs/ebib/ebib-2.49.1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+NEED_EMACS="27.1"
+
+inherit elisp
+
+DESCRIPTION="BibTeX database manager for Emacs"
+HOMEPAGE="https://joostkremers.github.io/ebib/
+	https://github.com/joostkremers/ebib/"
+
+if [[ "${PV}" == *9999* ]] ; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/joostkremers/${PN}.git"
+else
+	SRC_URI="https://github.com/joostkremers/${PN}/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz"
+
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="BSD"
+SLOT="0"
+
+RDEPEND="
+	>=app-emacs/compat-30.0.0.0
+	>=app-emacs/parsebib-6.2
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		app-emacs/with-simulated-input
+	)
+"
+
+DOCS=( README.md docs )
+SITEFILE="50${PN}-gentoo.el"
+
+elisp-enable-tests ert-runner test
+
+src_install() {
+	elisp_src_install
+
+	doinfo "${PN}.info"
+}