2 files changed, 83 insertions, 0 deletions
diff --git a/dev-libs/intel-compute-runtime/Manifest b/dev-libs/intel-compute-runtime/Manifest
index 36f70acede77..99c8d70535a3 100644
--- a/dev-libs/intel-compute-runtime/Manifest
+++ b/dev-libs/intel-compute-runtime/Manifest
@@ -1 +1,2 @@
 DIST intel-compute-runtime-23.17.26241.15.tar.gz 6556461 BLAKE2B 3814d5d24b0a79ebadda0f3ee5d1d3b414e9fb26e8c693ba66449a9f0500c8ec2e11533aa02142757e5177ad4c5efc5dd61a9c7db5a883a2cf4e9faab599ab4b SHA512 bd648fa964a15df76d1694af138f7c383239ccc5061cdd7faac0c45da3cffe95441614026b9bddfb86790446042ccc1d4abc3ecc023c50a036835598076a77bb
+DIST intel-compute-runtime-23.17.26241.24.tar.gz 6562120 BLAKE2B a75299259f1a41daeff14b75b87140953baa79e75390f48ce64d614b0837341505c331178aa86e59e4bd678fb4409f51ca494d14b6d112b4b9219506ad5c75b3 SHA512 e82798cf4c0e8511bb64f6e5543e7b49232cc9c1027ec374ec5c2cbfac8848263a5cc72072fadfe1e19920f5bdf65ceaed465ea88d4b2baec3acac433d383978
diff --git a/dev-libs/intel-compute-runtime/intel-compute-runtime-23.17.26241.24.ebuild b/dev-libs/intel-compute-runtime/intel-compute-runtime-23.17.26241.24.ebuild
new file mode 100644
index 000000000000..fadfb30dc042
--- /dev/null
+++ b/dev-libs/intel-compute-runtime/intel-compute-runtime-23.17.26241.24.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CMAKE_BUILD_TYPE="Release"
+MY_PN="${PN/intel-/}"
+MY_P="${MY_PN}-${PV}"
+
+inherit cmake flag-o-matic
+
+DESCRIPTION="Intel Graphics Compute Runtime for oneAPI Level Zero and OpenCL Driver"
+HOMEPAGE="https://github.com/intel/compute-runtime"
+SRC_URI="https://github.com/intel/${MY_PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+l0 +vaapi"
+
+RDEPEND=">=media-libs/gmmlib-22.3.5:="
+
+DEPEND="
+	${DEPEND}
+	dev-libs/intel-metrics-discovery:=
+	dev-libs/intel-metrics-library:=
+	dev-libs/libnl:3
+	dev-libs/libxml2:2
+	>=dev-util/intel-graphics-compiler-1.0.13860.4
+	>=dev-util/intel-graphics-system-controller-0.8.7:=
+	media-libs/mesa
+	>=virtual/opencl-3
+	l0? ( >=dev-libs/level-zero-1.11.0:= )
+	vaapi? (
+		x11-libs/libdrm[video_cards_intel]
+		media-libs/libva
+	)
+"
+
+BDEPEND="virtual/pkgconfig"
+
+DOCS=( "README.md" "FAQ.md" )
+
+PATCHES=(
+	"${FILESDIR}/${PN}-22.24.23453-remove-fortify-sources.patch"
+)
+
+src_prepare() {
+	# Remove '-Werror' from default
+	sed -e '/Werror/d' -i CMakeLists.txt || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	# See https://github.com/intel/compute-runtime/issues/531
+	filter-lto
+
+	local mycmakeargs=(
+		-DCCACHE_ALLOWED="OFF"
+		-DCMAKE_INSTALL_PREFIX="${EPREFIX}/usr"
+		-DCMAKE_INSTALL_LIBDIR="$(get_libdir)"
+		-DBUILD_WITH_L0="$(usex l0)"
+		-DDISABLE_LIBVA="$(usex !vaapi)"
+		-DNEO__METRICS_LIBRARY_INCLUDE_DIR="${ESYSROOT}/usr/include"
+		-DKHRONOS_GL_HEADERS_DIR="${ESYSROOT}/usr/include"
+		-DOCL_ICD_VENDORDIR="${EPREFIX}/etc/OpenCL/vendors"
+		-DSUPPORT_DG1="ON"
+		-Wno-dev
+
+		# See https://github.com/intel/intel-graphics-compiler/issues/204
+		# -DNEO_DISABLE_BUILTINS_COMPILATION="ON"
+
+		# If enabled, tests are automatically run during
+		# the compile phase and we cannot run them because
+		# they require permissions to access the hardware.
+		-DSKIP_UNIT_TESTS="1"
+	)
+
+	cmake_src_configure
+}