1 files changed, 47 insertions, 0 deletions
diff --git a/dev-python/cffi/cffi-1.14.4.ebuild b/dev-python/cffi/cffi-1.14.4.ebuild
new file mode 100644
index 000000000000..3fab57839c0d
--- /dev/null
+++ b/dev-python/cffi/cffi-1.14.4.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+# DO NOT ADD pypy to PYTHON_COMPAT
+# pypy bundles a modified version of cffi. Use python_gen_cond_dep instead.
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{6,7,8,9} )
+
+inherit distutils-r1 toolchain-funcs
+
+DESCRIPTION="Foreign Function Interface for Python calling C code"
+HOMEPAGE="https://cffi.readthedocs.io/ https://pypi.org/project/cffi/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+DEPEND="dev-libs/libffi:="
+RDEPEND="${DEPEND}
+	dev-python/pycparser[${PYTHON_USEDEP}]"
+BDEPEND="${RDEPEND}
+	virtual/pkgconfig
+	test? ( dev-python/pytest[${PYTHON_USEDEP}] )"
+
+distutils_enable_sphinx doc/source
+
+PATCHES=(
+	"${FILESDIR}"/cffi-1.14.0-darwin-no-brew.patch
+)
+
+src_configure() {
+	tc-export PKG_CONFIG
+}
+
+python_test() {
+	"${EPYTHON}" -c "import _cffi_backend as backend" || die
+	pytest -x -vv \
+		--ignore testing/test_zintegration.py \
+		--ignore testing/embedding \
+		c/ testing/ \
+		|| die "Testing failed with ${EPYTHON}"
+}