3 files changed, 73 insertions, 0 deletions
diff --git a/media-gfx/ueberzugpp/Manifest b/media-gfx/ueberzugpp/Manifest
new file mode 100644
index 000000000000..6ada33d3f14a
--- /dev/null
+++ b/media-gfx/ueberzugpp/Manifest
@@ -0,0 +1 @@
+DIST ueberzugpp-2.8.0.tar.gz 38768 BLAKE2B 80c879196339e3ce8fc5aeb2a87df8d3785021f72e5c0e47c55026d5cefc8cd3caa2174fea8413c642f54190970480488a6ec09d93e765b59dcf6616369dfbb7 SHA512 a5fceec97300cc3ada6c087fadc3b2d70f574207c5fd3f682c1a56b877c2b76ff40abe0ae76767e22ae82742be2bedee782e0ec86d200d28a15061bc1b4c2696
diff --git a/media-gfx/ueberzugpp/metadata.xml b/media-gfx/ueberzugpp/metadata.xml
new file mode 100644
index 000000000000..19342d5360ec
--- /dev/null
+++ b/media-gfx/ueberzugpp/metadata.xml
@@ -0,0 +1,14 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>ionen@gentoo.org</email>
+		<name>Ionen Wolkens</name>
+	</maintainer>
+	<use>
+		<flag name="opencv">Use <pkg>media-libs/opencv</pkg> for additional image formats and OpenCL accelerated scaling</flag>
+	</use>
+	<upstream>
+		<remote-id type="github">jstkdng/ueberzugpp</remote-id>
+	</upstream>
+</pkgmetadata>
diff --git a/media-gfx/ueberzugpp/ueberzugpp-2.8.0.ebuild b/media-gfx/ueberzugpp/ueberzugpp-2.8.0.ebuild
new file mode 100644
index 000000000000..f096268d66ed
--- /dev/null
+++ b/media-gfx/ueberzugpp/ueberzugpp-2.8.0.ebuild
@@ -0,0 +1,58 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Drop in replacement for ueberzug written in C++"
+HOMEPAGE="https://github.com/jstkdng/ueberzugpp/"
+SRC_URI="https://github.com/jstkdng/ueberzugpp/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="X opencv"
+
+RDEPEND="
+	dev-cpp/tbb:=
+	dev-libs/glib:2
+	dev-libs/libfmt:=
+	dev-libs/openssl:=
+	dev-libs/spdlog:=
+	media-libs/libsixel
+	media-libs/vips:=
+	net-libs/zeromq:=
+	X? (
+		x11-libs/libxcb:=
+		x11-libs/xcb-util-image
+	)
+	opencv? ( media-libs/opencv:= )
+	!media-gfx/ueberzug"
+DEPEND="
+	${RDEPEND}
+	dev-cpp/cli11
+	dev-cpp/nlohmann_json
+	net-libs/cppzmq
+	X? ( x11-base/xorg-proto )"
+
+src_configure() {
+	CMAKE_BUILD_TYPE=Release # install target wants this
+
+	local mycmakeargs=(
+		-DENABLE_OPENCV=$(usex opencv)
+		-DENABLE_X11=$(usex X)
+		-DENABLE_TURBOBASE64=no # not packaged
+		-DFETCHCONTENT_FULLY_DISCONNECTED=yes
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	# not handled by cmake, but upstream creates the pp symlink in their
+	# self-maintained AUR package and some scripts like ytfzf look for it
+	dosym ueberzug /usr/bin/${PN}
+}