Get Gentoo!
gentoo.org sites
gentoo.org Wiki Bugs Forums Packages
Planet Archives Sources
Infra Status
summaryrefslogtreecommitdiff
path: root/sci-geosciences/qgis
diff options
context:
space:
mode:
Diffstat (limited to 'sci-geosciences/qgis')
-rw-r--r--sci-geosciences/qgis/Manifest1
-rw-r--r--sci-geosciences/qgis/qgis-3.10.7.ebuild204
-rw-r--r--sci-geosciences/qgis/qgis-9999.ebuild40
3 files changed, 224 insertions, 21 deletions
diff --git a/sci-geosciences/qgis/Manifest b/sci-geosciences/qgis/Manifest
index a651738f867a..ed4b39165432 100644
--- a/sci-geosciences/qgis/Manifest
+++ b/sci-geosciences/qgis/Manifest
@@ -1,3 +1,4 @@
DIST qgis-3.10.2.tar.bz2 101916273 BLAKE2B 4b5d424348609e8fd1822ea9594fb11d30ae060aff15d8d962a1b15a602c1bdf5d8a17976c5a487ded5e5764e7367b8024aa52f9620ba0ec57fb075426a3c9f2 SHA512 d2ba31a8b50e0fec901d89dba6ca8467a9e26033197e78c56caaf7cce6b9bb7a1617a75f8e6275356f921ba9e986611384ab77890a4d7f5911d632e42466bb9f
DIST qgis-3.10.3.tar.bz2 102032791 BLAKE2B f64375438698f5477162644dc233e1014e6b541c5630398daa164582c3fb9130516144a9b0a5405948923416c1239cfa5260ee1e2f195b437044b0ae1bb29b9f SHA512 05501763e6ff38caa3b527e2f800da945bc08a9a194aae531c4466b76bc8bd18582e2ed5eceb82affaeec3db895ab9e36b3e09c9a4c7b3406bf98c88d54cc1a4
+DIST qgis-3.10.7.tar.bz2 102154692 BLAKE2B 9b54d542770f149eb3c413ef867a012e28e4121ff38114ef954131f55dea54cc8c0d4e65a5e8eac9098fb596af7b8d2f77ddfb2f8d0170d2e1a5b59569952151 SHA512 b10d81d24c7cfb8b285b6d9884dfe19ba33b032cd843d29b879159d203454fd359a669047b677baf515d92ce331ba66f59dc2466beae2048920b2c0da0c3d666
DIST qgis_sample_data-2.8.14.tar.gz 22119181 BLAKE2B 2d0565e91ec8119382bc9ab8e262dc04227fe8289146794891759ff5a32012245270614ba1119a6329fc45cf56852830c2079589309aa3467873f71f5c608eac SHA512 6b2653d5b57ffc2c2317639dac212429840984ac917ca3e452b39aabb99ea106d1a77c1c1dd967244ef16ede9deae751b170affdf08b72239eafed5b8977da3d
diff --git a/sci-geosciences/qgis/qgis-3.10.7.ebuild b/sci-geosciences/qgis/qgis-3.10.7.ebuild
new file mode 100644
index 000000000000..1d92f9dc32d7
--- /dev/null
+++ b/sci-geosciences/qgis/qgis-3.10.7.ebuild
@@ -0,0 +1,204 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+PYTHON_REQ_USE="sqlite"
+QTMIN="5.9.4"
+
+if [[ ${PV} = *9999 ]]; then
+ EGIT_REPO_URI="https://github.com/${PN}/${PN^^}.git"
+ inherit git-r3
+else
+ SRC_URI="https://qgis.org/downloads/${P}.tar.bz2
+ examples? ( https://qgis.org/downloads/data/qgis_sample_data.tar.gz -> qgis_sample_data-2.8.14.tar.gz )"
+ KEYWORDS="~amd64 ~x86"
+fi
+inherit cmake desktop python-single-r1 qmake-utils xdg
+
+DESCRIPTION="User friendly Geographic Information System"
+HOMEPAGE="https://www.qgis.org/"
+
+LICENSE="GPL-2+ GPL-3+"
+SLOT="0"
+IUSE="3d examples georeferencer grass hdf5 mapserver netcdf opencl oracle polar postgres python qml webkit"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE} mapserver? ( python )"
+
+BDEPEND="${PYTHON_DEPS}
+ >=dev-qt/linguist-tools-${QTMIN}:5
+ sys-devel/bison
+ sys-devel/flex
+"
+COMMON_DEPEND="
+ app-crypt/qca:2[qt5(+),ssl]
+ >=dev-db/spatialite-4.2.0
+ dev-db/sqlite:3
+ dev-libs/expat
+ dev-libs/libzip:=
+ dev-libs/qtkeychain[qt5(+)]
+ >=dev-qt/designer-${QTMIN}:5
+ >=dev-qt/qtconcurrent-${QTMIN}:5
+ >=dev-qt/qtcore-${QTMIN}:5
+ >=dev-qt/qtgui-${QTMIN}:5
+ >=dev-qt/qtnetwork-${QTMIN}:5[ssl]
+ >=dev-qt/qtpositioning-${QTMIN}:5
+ >=dev-qt/qtprintsupport-${QTMIN}:5
+ >=dev-qt/qtserialport-${QTMIN}:5
+ >=dev-qt/qtsvg-${QTMIN}:5
+ >=dev-qt/qtsql-${QTMIN}:5
+ >=dev-qt/qtwidgets-${QTMIN}:5
+ >=dev-qt/qtxml-${QTMIN}:5
+ media-gfx/exiv2:=
+ >=sci-libs/gdal-3.0.4:=[geos]
+ sci-libs/geos
+ sci-libs/libspatialindex:=
+ >=sci-libs/proj-6.3.1:=
+ >=x11-libs/qscintilla-2.10.1:=[qt5(+)]
+ >=x11-libs/qwt-6.1.2:6=[qt5(+),svg]
+ 3d? ( >=dev-qt/qt3d-${QTMIN}:5 )
+ georeferencer? ( sci-libs/gsl:= )
+ grass? ( =sci-geosciences/grass-7*:= )
+ hdf5? ( sci-libs/hdf5:= )
+ mapserver? ( dev-libs/fcgi )
+ netcdf? ( sci-libs/netcdf:= )
+ opencl? ( virtual/opencl )
+ oracle? (
+ dev-db/oracle-instantclient:=
+ sci-libs/gdal:=[oracle]
+ )
+ polar? ( >=x11-libs/qwtpolar-1.1.1-r1[qt5(+)] )
+ postgres? ( dev-db/postgresql:= )
+ python? (
+ ${PYTHON_DEPS}
+ $(python_gen_cond_dep '
+ dev-python/future[${PYTHON_MULTI_USEDEP}]
+ dev-python/httplib2[${PYTHON_MULTI_USEDEP}]
+ dev-python/jinja[${PYTHON_MULTI_USEDEP}]
+ dev-python/markupsafe[${PYTHON_MULTI_USEDEP}]
+ dev-python/owslib[${PYTHON_MULTI_USEDEP}]
+ dev-python/pygments[${PYTHON_MULTI_USEDEP}]
+ dev-python/PyQt5[designer,network,sql,svg,webkit?,${PYTHON_MULTI_USEDEP}]
+ dev-python/python-dateutil[${PYTHON_MULTI_USEDEP}]
+ dev-python/pytz[${PYTHON_MULTI_USEDEP}]
+ dev-python/pyyaml[${PYTHON_MULTI_USEDEP}]
+ >=dev-python/qscintilla-python-2.10.1[qt5(+),${PYTHON_MULTI_USEDEP}]
+ dev-python/requests[${PYTHON_MULTI_USEDEP}]
+ dev-python/sip:=[${PYTHON_MULTI_USEDEP}]
+ dev-python/six[${PYTHON_MULTI_USEDEP}]
+ >=sci-libs/gdal-2.2.3[python,${PYTHON_MULTI_USEDEP}]
+ postgres? ( dev-python/psycopg:2[${PYTHON_MULTI_USEDEP}] )
+ ')
+ )
+ qml? ( >=dev-qt/qtdeclarative-${QTMIN}:5 )
+ webkit? ( >=dev-qt/qtwebkit-5.9.1:5 )
+"
+DEPEND="${COMMON_DEPEND}
+ >=dev-qt/qttest-${QTMIN}:5
+"
+RDEPEND="${COMMON_DEPEND}
+ sci-geosciences/gpsbabel
+"
+
+# Disabling test suite because upstream disallow running from install path
+RESTRICT="test"
+
+PATCHES=(
+ # git master
+ "${FILESDIR}/${PN}-3.10.0-cmake-lib-suffix.patch"
+ # TODO upstream
+ "${FILESDIR}/${PN}-3.4.7-featuresummary.patch"
+ "${FILESDIR}/${PN}-3.4.7-default-qmldir.patch"
+)
+
+pkg_setup() {
+ python-single-r1_pkg_setup
+}
+
+src_prepare() {
+ cmake_src_prepare
+}
+
+src_configure() {
+ local mycmakeargs=(
+ -DQGIS_MANUAL_SUBDIR=share/man/
+ -DQGIS_LIB_SUBDIR=$(get_libdir)
+ -DQGIS_PLUGIN_SUBDIR=$(get_libdir)/qgis
+ -DQWT_INCLUDE_DIR=/usr/include/qwt6
+ -DQWT_LIBRARY=/usr/$(get_libdir)/libqwt6-qt5.so
+ -DPEDANTIC=OFF
+ -DUSE_CCACHE=OFF
+ -DWITH_ANALYSIS=ON
+ -DWITH_APIDOC=OFF
+ -DWITH_GUI=ON
+ -DWITH_INTERNAL_MDAL=ON # not packaged, bug 684538
+ -DWITH_QSPATIALITE=ON
+ -DENABLE_TESTS=OFF
+ -DWITH_3D=$(usex 3d)
+ -DWITH_GEOREFERENCER=$(usex georeferencer)
+ -DWITH_GRASS7=$(usex grass)
+ $(cmake_use_find_package hdf5 HDF5)
+ -DWITH_SERVER=$(usex mapserver)
+ $(cmake_use_find_package netcdf NetCDF)
+ -DUSE_OPENCL=$(usex opencl)
+ -DWITH_ORACLE=$(usex oracle)
+ -DWITH_QWTPOLAR=$(usex polar)
+ -DWITH_POSTGRESQL=$(usex postgres)
+ -DWITH_BINDINGS=$(usex python)
+ -DWITH_CUSTOM_WIDGETS=$(usex python)
+ -DWITH_QUICK=$(usex qml)
+ -DWITH_QTWEBKIT=$(usex webkit)
+ )
+
+ if use grass; then
+ mycmakeargs+=(
+ -DGRASS_PREFIX7=/usr/$(get_libdir)/grass70
+ )
+ fi
+
+ use python && mycmakeargs+=( -DBINDINGS_GLOBAL_INSTALL=ON )
+
+ # bugs 612956, 648726
+ addpredict /dev/dri/renderD128
+ addpredict /dev/dri/renderD129
+
+ cmake_src_configure
+}
+
+src_install() {
+ cmake_src_install
+
+ insinto /usr/share/mime/packages
+ doins debian/qgis.xml
+
+ if use examples; then
+ docinto examples
+ dodoc -r "${WORKDIR}"/qgis_sample_data/.
+ docompress -x /usr/share/doc/${PF}/examples
+ fi
+
+ if use python; then
+ python_optimize
+ python_optimize "${ED}"/usr/share/qgis/python
+ fi
+
+ if use grass; then
+ python_fix_shebang "${ED}"/usr/share/qgis/grass/scripts
+ fi
+}
+
+pkg_postinst() {
+ if use postgres; then
+ elog "If you don't intend to use an external PostGIS server"
+ elog "you should install:"
+ elog " dev-db/postgis"
+ elif use python; then
+ elog "Support of PostgreSQL is disabled."
+ elog "But some installed python-plugins import the psycopg2 module."
+ elog "If you do not need these plugins just disable them"
+ elog "in the Plugins menu, else you need to set USE=\"postgres\""
+ fi
+
+ xdg_pkg_postinst
+}
diff --git a/sci-geosciences/qgis/qgis-9999.ebuild b/sci-geosciences/qgis/qgis-9999.ebuild
index 74129055f6bb..1d92f9dc32d7 100644
--- a/sci-geosciences/qgis/qgis-9999.ebuild
+++ b/sci-geosciences/qgis/qgis-9999.ebuild
@@ -5,7 +5,7 @@ EAPI=7
PYTHON_COMPAT=( python3_{6,7,8} )
PYTHON_REQ_USE="sqlite"
-QT_MIN_VER="5.9.4"
+QTMIN="5.9.4"
if [[ ${PV} = *9999 ]]; then
EGIT_REPO_URI="https://github.com/${PN}/${PN^^}.git"
@@ -26,9 +26,8 @@ IUSE="3d examples georeferencer grass hdf5 mapserver netcdf opencl oracle polar
REQUIRED_USE="${PYTHON_REQUIRED_USE} mapserver? ( python )"
-BDEPEND="
- ${PYTHON_DEPS}
- >=dev-qt/linguist-tools-${QT_MIN_VER}:5
+BDEPEND="${PYTHON_DEPS}
+ >=dev-qt/linguist-tools-${QTMIN}:5
sys-devel/bison
sys-devel/flex
"
@@ -39,26 +38,26 @@ COMMON_DEPEND="
dev-libs/expat
dev-libs/libzip:=
dev-libs/qtkeychain[qt5(+)]
- >=dev-qt/designer-${QT_MIN_VER}:5
- >=dev-qt/qtconcurrent-${QT_MIN_VER}:5
- >=dev-qt/qtcore-${QT_MIN_VER}:5
- >=dev-qt/qtgui-${QT_MIN_VER}:5
- >=dev-qt/qtnetwork-${QT_MIN_VER}:5[ssl]
- >=dev-qt/qtpositioning-${QT_MIN_VER}:5
- >=dev-qt/qtprintsupport-${QT_MIN_VER}:5
- >=dev-qt/qtserialport-${QT_MIN_VER}:5
- >=dev-qt/qtsvg-${QT_MIN_VER}:5
- >=dev-qt/qtsql-${QT_MIN_VER}:5
- >=dev-qt/qtwidgets-${QT_MIN_VER}:5
- >=dev-qt/qtxml-${QT_MIN_VER}:5
+ >=dev-qt/designer-${QTMIN}:5
+ >=dev-qt/qtconcurrent-${QTMIN}:5
+ >=dev-qt/qtcore-${QTMIN}:5
+ >=dev-qt/qtgui-${QTMIN}:5
+ >=dev-qt/qtnetwork-${QTMIN}:5[ssl]
+ >=dev-qt/qtpositioning-${QTMIN}:5
+ >=dev-qt/qtprintsupport-${QTMIN}:5
+ >=dev-qt/qtserialport-${QTMIN}:5
+ >=dev-qt/qtsvg-${QTMIN}:5
+ >=dev-qt/qtsql-${QTMIN}:5
+ >=dev-qt/qtwidgets-${QTMIN}:5
+ >=dev-qt/qtxml-${QTMIN}:5
media-gfx/exiv2:=
>=sci-libs/gdal-3.0.4:=[geos]
sci-libs/geos
sci-libs/libspatialindex:=
- >=sci-libs/proj-4.9.3:=
+ >=sci-libs/proj-6.3.1:=
>=x11-libs/qscintilla-2.10.1:=[qt5(+)]
>=x11-libs/qwt-6.1.2:6=[qt5(+),svg]
- 3d? ( >=dev-qt/qt3d-${QT_MIN_VER}:5 )
+ 3d? ( >=dev-qt/qt3d-${QTMIN}:5 )
georeferencer? ( sci-libs/gsl:= )
grass? ( =sci-geosciences/grass-7*:= )
hdf5? ( sci-libs/hdf5:= )
@@ -92,12 +91,11 @@ COMMON_DEPEND="
postgres? ( dev-python/psycopg:2[${PYTHON_MULTI_USEDEP}] )
')
)
- qml? ( >=dev-qt/qtdeclarative-${QT_MIN_VER}:5 )
+ qml? ( >=dev-qt/qtdeclarative-${QTMIN}:5 )
webkit? ( >=dev-qt/qtwebkit-5.9.1:5 )
"
DEPEND="${COMMON_DEPEND}
- >=dev-qt/qttest-${QT_MIN_VER}:5
- python? ( ${PYTHON_DEPS} )
+ >=dev-qt/qttest-${QTMIN}:5
"
RDEPEND="${COMMON_DEPEND}
sci-geosciences/gpsbabel