1 files changed, 59 insertions, 0 deletions
diff --git a/www-apps/grafana-bin/grafana-bin-4.2.0-r1.ebuild b/www-apps/grafana-bin/grafana-bin-4.2.0-r1.ebuild
new file mode 100644
index 000000000000..2afa441185f1
--- /dev/null
+++ b/www-apps/grafana-bin/grafana-bin-4.2.0-r1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+inherit user systemd
+
+MY_PN=${PN/-bin/}
+S=${WORKDIR}/${MY_PN}-${PV}
+
+DESCRIPTION="Gorgeous metric viz, dashboards & editors for Graphite, InfluxDB & OpenTSDB"
+HOMEPAGE="http://grafana.org"
+SRC_URI="https://s3-us-west-2.amazonaws.com/grafana-releases/release/${MY_PN}-${PV}.linux-x64.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+DEPEND=""
+RDEPEND="
+	${DEPEND}
+	app-admin/logrotate"
+
+QA_EXECSTACK="usr/share/grafana/vendor/phantomjs/phantomjs"
+QA_PRESTRIPPED=${QA_EXECSTACK}
+
+pkg_setup() {
+	enewgroup grafana
+	enewuser grafana -1 -1 /usr/share/grafana grafana
+}
+
+src_install() {
+	keepdir /etc/grafana
+	insinto /etc/grafana
+	newins "${S}"/conf/sample.ini grafana.ini
+	rm "${S}"/conf/sample.ini || die
+
+	# Frontend assets
+	insinto /usr/share/${MY_PN}
+	doins -r public conf vendor
+
+	dobin bin/grafana-cli
+	dobin bin/grafana-server
+
+	newconfd "${FILESDIR}"/grafana.confd grafana
+	newinitd "${FILESDIR}"/grafana.initd.3 grafana
+	systemd_newunit "${FILESDIR}"/grafana.service grafana.service
+
+	keepdir /var/{lib,log}/grafana
+	keepdir /var/lib/grafana/{dashboards,plugins}
+	fowners grafana:grafana /var/{lib,log}/grafana
+	fowners grafana:grafana /var/lib/grafana/{dashboards,plugins}
+	fperms 0750 /var/{lib,log}/grafana
+	fperms 0750 /var/lib/grafana/{dashboards,plugins}
+
+	# Logrotation support.
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}"/grafana.logrotate "${PN}"
+}