blob: 0566308b2aee037516fbe2b21deae941767cc66d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_{7..8} )
DISTUTILS_SINGLE_IMPL=1
DISTUTILS_USE_SETUPTOOLS="rdepend"
inherit distutils-r1 systemd
DESCRIPTION="Automatically create, prune and verify backups with borgbackup"
HOMEPAGE="https://torsion.org/borgmatic/"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
LICENSE="GPL-3"
SLOT="0"
KEYWORDS="amd64"
# Fails due to problems with dev-python/flexmock-0.10.4; see Bug #740128
RESTRICT="test"
# borg is called as an external tool, hence no pythonic stuff
RDEPEND="app-backup/borgbackup
$(python_gen_cond_dep '
dev-python/colorama[${PYTHON_USEDEP}]
>=dev-python/pykwalify-1.6.0[${PYTHON_USEDEP}]
dev-python/requests[${PYTHON_USEDEP}]
<dev-python/ruamel-yaml-0.17.0[${PYTHON_USEDEP}]
')"
BDEPEND="
test? (
$(python_gen_cond_dep '
dev-python/flexmock[${PYTHON_USEDEP}]
')
)"
PATCHES=(
"${FILESDIR}"/${PN}-1.5.1-systemd_service_bin_path.patch
"${FILESDIR}"/${PN}-1.5.1-no_test_coverage.patch
)
distutils_enable_tests pytest
src_prepare() {
distutils-r1_src_prepare
# Unlike the other two test files in integration/commands, which use the
# relevant modules' respective APIs, test_borgmatic.py tries to call the
# 'borgmatic' executable - which by the time we execute src_test will
# not have been created yet. distutils_install_for_testing would likely
# take care of this - but between the aforementioned behaviour inconsistency
# and the fact the only test run from this file as of version 1.5.1 is the
# parsing of contents of 'borgmatic --version', just skip it for now.
rm -f "${S}"/tests/integration/commands/test_borgmatic.py
}
src_install() {
distutils-r1_src_install
systemd_dounit sample/systemd/borgmatic.{service,timer}
keepdir /etc/borgmatic
}
pkg_postinst() {
if [[ -z "${REPLACING_VERSIONS}" ]]; then
elog "To generate a sample configuration file, run:"
elog " generate-borgmatic-config"
fi
elog
elog "Systemd users wishing to periodically run borgmatic can use the provided timer and service units."
}
|
GitWeb
