app-text/rarian/rarian-0.8.4.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40

# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DESCRIPTION="A documentation metadata library"
HOMEPAGE="https://rarian.freedesktop.org/"
SRC_URI="https://gitlab.freedesktop.org/rarian/rarian/-/releases/${PV}/downloads/assets/${P}.tar.bz2"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux"

IUSE="test"
RESTRICT="!test? ( test )"

COMMON_DEPEND="
	dev-libs/libxslt
	dev-libs/tinyxml
"
DEPEND="${COMMON_DEPEND}
	test? ( >=dev-libs/check-0.9.6 )
"
RDEPEND="${COMMON_DEPEND}
	sys-apps/util-linux
"

src_configure() {
	local myconf=(
		--localstatedir="${EPREFIX}"/var
		$(use_with test check)
	)
	econf "${myconf[@]}"
}

src_install() {
	default
	keepdir /var/lib/rarian
	find "${ED}" -name '*.la' -delete || die
}