blob: 7cb1ea92dafba8baca6f807cdfa4b671e5ce6474 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
# Please do not apply any patches which affect the generated output from
# `autoconf`, as this package is used to submit patches upstream.
inherit toolchain-autoconf
MY_PN=${PN/-vanilla}
MY_P=${MY_PN}-${PV}
DESCRIPTION="Used to create autoconfiguration files"
HOMEPAGE="https://www.gnu.org/software/autoconf/autoconf.html"
SRC_URI="mirror://gnu/${MY_PN}/${MY_P}.tar.gz"
S="${WORKDIR}"/${MY_P}
LICENSE="GPL-2"
SLOT="${PV:0:3}"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
IUSE="test"
RESTRICT="!test? ( test )"
BDEPEND="
dev-lang/perl
sys-devel/m4
test? ( dev-util/dejagnu )
"
RDEPEND="
${BDEPEND}
sys-apps/texinfo
>=dev-build/autoconf-wrapper-13
"
PATCHES=(
"${FILESDIR}"/${MY_P}-gentoo.patch
"${FILESDIR}"/${MY_P}-destdir.patch
"${FILESDIR}"/${MY_P}-test-fixes.patch #146592
"${FILESDIR}"/${MY_P}-perl-5.26.patch
)
src_configure() {
# need to include --exec-prefix and --bindir or our
# DESTDIR patch will trigger sandbox hate :(
#
# need to force locale to C to avoid bugs in the old
# configure script breaking the install paths #351982
#
# force to `awk` so that we don't encode another awk that
# happens to currently be installed, but might later be
# uninstalled (like mawk). same for m4.
export ac_cv_path_M4="m4" ac_cv_prog_AWK="awk"
export LC_ALL=C
toolchain-autoconf_src_configure \
--exec-prefix="${EPREFIX}"/usr \
--bindir="${EPREFIX}"/usr/bin \
--datadir="${EPREFIX}"/usr/share/"${P}" \
--infodir="${TC_AUTOCONF_INFOPATH}"
}
|
GitWeb
