dev-erlang/protobuffs/protobuffs-0.9.0.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40

# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI=6

inherit rebar

MY_PN="erlang_protobuffs"
MY_P="${MY_PN}-${PV}"

DESCRIPTION="Google's Protocol Buffers for Erlang"
HOMEPAGE="https://github.com/basho/erlang_protobuffs"
SRC_URI="https://github.com/basho/${MY_PN}/archive/${PV}.tar.gz
	-> ${P}.tar.gz"

LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="amd64 ~arm ~ia64 ppc ~sparc x86"
IUSE="test"

CDEPEND=">=dev-lang/erlang-17.1"
DEPEND="${CDEPEND}
	test? (
		>=dev-erlang/meck-0.8.2
		>=dev-erlang/proper-1.1
	)"
RDEPEND="${CDEPEND}"

DOCS=( AUTHORS  ChangeLog  README.md RELNOTES.md )

S="${WORKDIR}/${MY_P}"

src_test() {
	./scripts/generate_emakefile.escript || die
	erebar ct
	# FIXME: 1 test fails, reported upstream:
	# FIXME: https://github.com/basho/erlang_protobuffs/issues/100
	# FIXME: erebar eunit
}