blob: 24024951426a52d7492fbc6e4c4d9cbf292f032f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=hatchling
PYTHON_COMPAT=( python3_{10..13} python3_13t pypy3 )
inherit distutils-r1 pypi
DESCRIPTION="Rapid multi-Python deployment"
HOMEPAGE="
https://codespeak.net/execnet/
https://github.com/pytest-dev/execnet/
https://pypi.org/project/execnet/
"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~x64-macos"
BDEPEND="
dev-python/hatch-vcs[${PYTHON_USEDEP}]
"
distutils_enable_sphinx doc
distutils_enable_tests pytest
python_test() {
local EPYTEST_DESELECT=()
case ${EPYTHON} in
python3.13t)
EPYTEST_DESELECT+=(
# https://github.com/pytest-dev/execnet/issues/306
testing/test_channel.py::TestChannelBasicBehaviour::test_channel_callback_remote_freed
)
;;
esac
# the test suite checks if bytecode writing can be disabled/enabled
local -x PYTHONDONTWRITEBYTECODE=
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
# some tests are implicitly run against both sys.executable
# and pypy3, which is redundant and results in pypy3 bytecode being
# written to cpython install dirs
epytest testing -k "not pypy3"
}
|
GitWeb
