blob: 80e7699557cd1daf3288eb2a6b1967a2aa120477 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python2_7 python3_{5,6,7} )
inherit distutils-r1 multiprocessing
MY_P=llvm-${PV/_/}.src
DESCRIPTION="A stand-alone install of the LLVM suite testing tool"
HOMEPAGE="https://llvm.org/"
SRC_URI="https://releases.llvm.org/${PV}/${MY_P}.tar.xz"
S=${WORKDIR}/${MY_P}/utils/lit
LICENSE="Apache-2.0-with-LLVM-exceptions UoI-NCSA"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86 ~amd64-fbsd"
IUSE="test"
RESTRICT="!test? ( test )"
# Tests require 'FileCheck' and 'not' utilities (from llvm)
BDEPEND="
dev-python/setuptools[${PYTHON_USEDEP}]
test? (
dev-python/psutil[${PYTHON_USEDEP}]
sys-devel/llvm )"
# TODO: move the manpage generation here (from sys-devel/llvm)
src_unpack() {
einfo "Unpacking parts of ${MY_P}.tar.xz ..."
tar -xJf "${DISTDIR}/${MY_P}.tar.xz" "${MY_P}/utils/lit" || die
}
python_test() {
local -x LIT_PRESERVES_TMP=1
./lit.py -j "${LIT_JOBS:-$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")}" \
-vv tests || die
}
|
GitWeb
