blob: 1cda7fec1dfa37bff0b5b3ebc2458b9fa883fa1f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_EXT=1
DISTUTILS_USE_PEP517=setuptools
PYPI_NO_NORMALIZE=1
PYPI_PN=netCDF4
PYTHON_COMPAT=( python3_{10..11} )
inherit distutils-r1 optfeature pypi
DESCRIPTION="Python/numpy interface to the netCDF C library"
HOMEPAGE="
https://unidata.github.io/netcdf4-python/
https://github.com/unidata/netcdf4-python/
https://pypi.org/project/netCDF4/
"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="test"
RESTRICT="!test? ( test )"
DEPEND="
dev-python/numpy[${PYTHON_USEDEP}]
sci-libs/hdf5:=
sci-libs/netcdf:=[hdf5]
"
RDEPEND="
${DEPEND}
dev-python/certifi[${PYTHON_USEDEP}]
dev-python/cftime[${PYTHON_USEDEP}]
"
BDEPEND="
dev-python/cython[${PYTHON_USEDEP}]
test? (
${RDEPEND}
sci-libs/netcdf[tools(+)]
)
"
python_test() {
local -x NO_NET=1
cd test || die
"${EPYTHON}" run_all.py || die
}
pkg_postinst() {
optfeature "HDF4 support" sci-libs/hdf "sci-libs/netcdf[hdf]"
optfeature "MPI parallel IO support" "sci-libs/hdf5[mpi]" "sci-libs/netcdf[mpi]"
optfeature "OPeNDAP support" net-misc/curl "sci-libs/netcdf[dap]"
}
|
GitWeb
