blob: 9078a14c5381e33cfbc48152256bce58a886a5d1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
DISTUTILS_USE_SETUPTOOLS=rdepend
PYTHON_COMPAT=( python3_{7..9} )
inherit cmake distutils-r1
DESCRIPTION="AST-based Python refactoring library"
HOMEPAGE="https://pybind11.readthedocs.io/en/stable/"
SRC_URI="https://github.com/pybind/pybind11/archive/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
RDEPEND="
dev-cpp/eigen:3
"
distutils_enable_sphinx docs \
'<dev-python/sphinx-3' \
dev-python/breathe \
dev-python/sphinx_rtd_theme
distutils_enable_tests pytest
python_prepare_all() {
export PYBIND11_USE_CMAKE=1
# broken with scipy-1.4.1
sed -i -e 's:test_sparse:_&:' tests/test_eigen.py || die
cmake_src_prepare
distutils-r1_python_prepare_all
}
python_configure() {
local mycmakeargs=(
# disable forced lto
-DPYBIND11_LTO_CXX_FLAGS=
-DPYBIND11_INSTALL=ON
-DPYBIND11_TEST=$(usex test)
)
cmake_src_configure
}
python_compile() {
distutils-r1_python_compile
# Compilation only does anything for tests
use test && cmake_src_compile
}
python_test() {
cmake_build check
}
python_install() {
distutils-r1_python_install
cmake_src_install
}
|
GitWeb
