dev-python/pydiffx/pydiffx-1.1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43

# Copyright 2022-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{9..11} )

inherit distutils-r1

MY_P=diffx-pydiffx-release-${PV}
DESCRIPTION="Python module for reading and writing DiffX files"
HOMEPAGE="
	https://diffx.org/pydiffx/
	https://github.com/beanbaginc/diffx/
	https://pypi.org/project/pydiffx/
"
SRC_URI="
	https://github.com/beanbaginc/diffx/archive/pydiffx/release-${PV}.tar.gz
		-> ${MY_P}.gh.tar.gz
"
S=${WORKDIR}/${MY_P}/python

LICENSE="MIT"
SLOT="0"
KEYWORDS="amd64 x86"

RDEPEND="
	dev-python/six[${PYTHON_USEDEP}]
"
BDEPEND="
	test? (
		dev-python/kgb[${PYTHON_USEDEP}]
	)
"

distutils_enable_tests unittest

src_prepare() {
	# remove .dev tag that breaks revdeps
	sed -e '/tag_build/d' -i setup.cfg || die
	distutils-r1_src_prepare
}