blob: d16ca40b80247012165872c0bec52f96f4d4f4ac (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_{7..10} )
inherit gnome.org meson python-r1 virtualx xdg
DESCRIPTION="Python bindings for GObject Introspection"
HOMEPAGE="https://pygobject.readthedocs.io/"
LICENSE="LGPL-2.1+"
SLOT="3"
KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
IUSE="+cairo examples test"
RESTRICT="!test? ( test )"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
RDEPEND="${PYTHON_DEPS}
>=dev-libs/glib-2.56:2
>=dev-libs/gobject-introspection-1.56:=
dev-libs/libffi:=
cairo? (
>=dev-python/pycairo-1.16.0[${PYTHON_USEDEP}]
x11-libs/cairo[glib] )
"
DEPEND="${RDEPEND}
test? (
dev-libs/atk[introspection]
dev-python/pytest[${PYTHON_USEDEP}]
x11-libs/gdk-pixbuf:2[introspection,jpeg]
x11-libs/gtk+:3[introspection]
x11-libs/pango[introspection]
)
"
BDEPEND="
virtual/pkgconfig
"
PATCHES=(
"${FILESDIR}"/${P}-dynamicimporter-py310.patch
)
src_configure() {
configuring() {
meson_src_configure \
$(meson_feature cairo pycairo) \
$(meson_use test tests) \
-Dpython="${EPYTHON}"
}
python_foreach_impl configuring
}
src_compile() {
python_foreach_impl meson_src_compile
}
src_test() {
local -x GIO_USE_VFS="local" # prevents odd issues with deleting ${T}/.gvfs
local -x GIO_USE_VOLUME_MONITOR="unix" # prevent udisks-related failures in chroots, bug #449484
testing() {
local -x XDG_CACHE_HOME="${T}/${EPYTHON}"
meson_src_test --timeout-multiplier 3 || die "test failed for ${EPYTHON}"
}
virtx python_foreach_impl testing
}
src_install() {
installing() {
meson_src_install
python_optimize
}
python_foreach_impl installing
use examples && dodoc -r examples
}
|
GitWeb