blob: 48af3396cfcbf339d970d0c35499f72b309c2451 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
|
# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=6
PYTHON_COMPAT=( python{2_7,3_4,3_5} )
inherit distutils-r1 virtualx xdg-utils
DESCRIPTION="Python module to parse ds9 region file"
HOMEPAGE="http://pyregion.readthedocs.org/"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
LICENSE="MIT"
IUSE="doc examples test"
RDEPEND="
dev-python/astropy[${PYTHON_USEDEP}]
dev-python/numpy[${PYTHON_USEDEP}]
dev-python/pyparsing[${PYTHON_USEDEP}]"
DEPEND="${RDEPEND}
dev-python/setuptools[${PYTHON_USEDEP}]
dev-python/astropy-helpers[${PYTHON_USEDEP}]
dev-python/cython[${PYTHON_USEDEP}]
doc? (
dev-python/sphinx[${PYTHON_USEDEP}]
dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
dev-python/wcsaxes[${PYTHON_USEDEP}] )
test? (
dev-python/pytest[${PYTHON_USEDEP}]
dev-python/matplotlib[${PYTHON_USEDEP}] )"
python_prepare_all() {
# use astropy-helpers from system
sed -i -e '/auto_use/s/True/False/' setup.cfg || die
xdg_environment_reset
distutils-r1_python_prepare_all
}
python_compile_all() {
if use doc; then
python_setup
VARTEXFONTS="${T}"/fonts \
MPLCONFIGDIR="${BUILD_DIR}" \
PYTHONPATH="${BUILD_DIR}"/lib \
esetup.py build_sphinx --no-intersphinx
fi
}
python_test() {
virtx esetup.py test
}
python_install_all() {
use doc && local HTML_DOCS=( docs/_build/html/. )
distutils-r1_python_install_all
if use examples; then
insinto /usr/share/doc/${PF}
doins -r examples
fi
}
|
GitWeb
