dev-python/tomli/tomli-1.2.1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35

# Copyright 2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

# please keep this ebuild at EAPI 7 -- sys-apps/portage dep
EAPI=7

PYTHON_COMPAT=( python3_{8..10} pypy3 )
inherit distutils-r1

DESCRIPTION="A lil' TOML parser"
HOMEPAGE="
	https://pypi.org/project/tomli/
	https://github.com/hukkin/tomli/"
SRC_URI="
	https://github.com/hukkin/tomli/archive/${PV}.tar.gz
		-> ${P}.gh.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x64-macos"

BDEPEND="
	test? ( dev-python/python-dateutil[${PYTHON_USEDEP}] )"

distutils_enable_tests pytest

src_prepare() {
	# we don't use pyproject.toml to avoid circular deps
	cat > setup.py <<-EOF || die
		from setuptools import setup
		setup(name="tomli", version="${PV}", packages=["tomli"], package_data={"": ["*"]})
	EOF

	distutils-r1_src_prepare
}