blob: ed8095d53b083349c6a286690b9fb9095afaeb31 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=5
# ruby24 -> code is not compatible
USE_RUBY="ruby21 ruby22 ruby23"
RUBY_FAKEGEM_TASK_TEST="test spec NO_CONNECTION=true"
RUBY_FAKEGEM_RECIPE_DOC="rdoc"
RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.md"
inherit ruby-fakegem
DESCRIPTION="Allows stubbing HTTP requests and setting expectations on HTTP requests"
HOMEPAGE="https://github.com/bblimke/webmock"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 ~arm ~arm64 ~ppc64 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris ~x86-solaris"
IUSE=""
ruby_add_rdepend ">=dev-ruby/addressable-2.3.6 >=dev-ruby/crack-0.3.2 dev-ruby/hashdiff"
ruby_add_bdepend "test? (
dev-ruby/minitest:5
dev-ruby/rspec:3
dev-ruby/rack
>=dev-ruby/httpclient-2.2.4
>=dev-ruby/patron-0.4.18
>=dev-ruby/http-0.8.0:0.8 )"
all_ruby_prepare() {
# Remove bundler support
rm Gemfile || die
sed -i -e '/[Bb]undler/d' Rakefile || die
# There is now optional support for curb and typhoeus which we don't
# have in Gentoo yet. em_http_request is available in Gentoo but its
# version is too old.
sed -i -e '/\(curb\|typhoeus\|em-http\)/d' spec/spec_helper.rb || die
rm spec/acceptance/{typhoeus,curb,excon,em_http_request}/* || die
}
each_ruby_test() {
${RUBY} -S rake test NO_CONNECTION=true || die
${RUBY} -S rspec-3 spec || die
einfo "Delay to allow the test server to stop"
sleep 10
}
|
GitWeb
