blob: c921f5b02f7e3b5a2e965d473e87b2a4fc027797 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI="6"
inherit autotools eapi7-ver
MY_P="${P^g}"
DESCRIPTION="A Unix system friendly Scheme Interpreter"
HOMEPAGE="http://practical-scheme.net/gauche/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tgz"
LICENSE="BSD"
SLOT="0/$(ver_cut 1-2)"
KEYWORDS="~alpha amd64 ~ia64 ~ppc ~ppc64 ~sparc x86 ~amd64-linux ~x86-linux ~x86-macos"
IUSE="ipv6 libressl mbedtls test"
RESTRICT="!test? ( test )"
RDEPEND="sys-libs/gdbm
mbedtls? ( net-libs/mbedtls:= )"
DEPEND="${RDEPEND}
test? (
!libressl? ( dev-libs/openssl:0 )
libressl? ( dev-libs/libressl:0 )
)"
S="${WORKDIR}/${MY_P}"
PATCHES=(
"${FILESDIR}"/${PN}-gauche.m4.patch
"${FILESDIR}"/${PN}-ext-ldflags.patch
"${FILESDIR}"/${PN}-xz-info.patch
"${FILESDIR}"/${P}-rfc.tls.patch
)
DOCS=( AUTHORS ChangeLog HACKING README )
src_prepare() {
default
use ipv6 && sed -i "s/ -4//" ext/tls/ssltest-mod.scm
eautoconf
}
src_configure() {
econf \
$(use_enable ipv6) \
--with-ca-bundle="${EPREFIX}"/etc/ssl/certs/ca-certificates.crt \
--with-libatomic-ops=no \
--with-slib="${EPREFIX}"/usr/share/slib \
--with-tls=axtls$(usex mbedtls ',mbedtls' '')
}
src_test() {
emake -j1 -s check
}
src_install() {
emake DESTDIR="${D}" install-pkg install-doc
einstalldocs
}
|
GitWeb
