blob: 89d7719e6af2e2732235839b92ec8e5610d4270c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
|
# Copyright 2020-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit cmake flag-o-matic
DESCRIPTION="A real-time noise suppression plugin for voice"
HOMEPAGE="https://github.com/werman/noise-suppression-for-voice"
if [[ "${PV}" == "9999" ]]; then
inherit git-r3
EGIT_REPO_URI="https://github.com/werman/noise-suppression-for-voice.git"
else
SRC_URI="https://github.com/werman/noise-suppression-for-voice/archive/v${PV}.tar.gz -> ${P}.tar.gz"
KEYWORDS="~amd64 ~x86"
fi
LICENSE="GPL-3+"
SLOT="0"
IUSE="lv2 vst vst3 test"
RESTRICT="!test? ( test )"
COMMON_DEPEND="
media-libs/freetype
x11-libs/libX11
x11-libs/libXcursor
x11-libs/libXinerama
x11-libs/libXrandr
"
DEPEND="
lv2? ( ${COMMON_DEPEND} )
vst? ( ${COMMON_DEPEND} )
vst3? ( ${COMMON_DEPEND} )
"
RDEPEND="${DEPEND}"
# Fixes for the JUCE issues the latter 3 patches work around have been
# submitted upstream, but have not been merged yet:
# https://github.com/juce-framework/JUCE/pull/1239
PATCHES=(
"${FILESDIR}/${P}-tests.patch"
"${FILESDIR}/${P}-Patch-out-use-of-execinfo.h.patch"
"${FILESDIR}/${P}-Patch-out-use-of-stat64.patch"
"${FILESDIR}/${P}-Patch-out-uses-of-nl_langinfo-for-musl.patch"
)
src_configure() {
# Bug #925672
append-atomic-flags
local mycmakeargs=(
-DBUILD_LADSPA_PLUGIN=ON
-DBUILD_LV2_PLUGIN=$(usex lv2 ON OFF)
-DBUILD_VST_PLUGIN=$(usex vst ON OFF)
-DBUILD_VST3_PLUGIN=$(usex vst3 ON OFF)
-DBUILD_TESTS=$(usex test ON OFF)
-DBUILD_AU_PLUGIN=OFF
-DBUILD_AUV3_PLUGIN=OFF
)
cmake_src_configure
}
src_test() {
cp "${BUILD_DIR}/src/common/CTestTestfile.cmake" "${BUILD_DIR}/CTestTestfile.cmake" || die
cmake_src_test
}
src_install() {
cmake_src_install
dodir /usr/share/pipewire/pipewire.conf.avail/
sed "s|%PATH_TO_LADSPA_PLUGIN%|${EPREFIX}/usr/$(get_libdir)/ladspa/librnnoise_ladspa.so|" \
"${FILESDIR}/99-input-denoising.conf" \
> "${D}/${EPREFIX}/usr/share/pipewire/pipewire.conf.avail/99-input-denoising.conf" || die
}
pkg_postinst() {
elog "An example PipeWire configuration has been installed into:"
elog "${EPREFIX}/usr/share/pipewire/pipewire.conf.avail/99-input-denoising.conf"
elog ""
elog "You can enable it by copying or symlinking the file into:"
elog " ~/.config/pipewire/pipewire.conf.d/ for your user, or"
elog " /etc/pipewire/pipewire.conf.d/ to enable it system-wide."
}
|
GitWeb