blob: 448b740211bffa7c89e3ba24ed89f1858a2640f9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PLOCALES="af ar be bg bn br bs ca cs cy da de el en en_CA en_GB eo es et eu fa fi fr ga gl he he_IL hi hr hu hy ia id is it ja ka kk ko lt lv mk_MK mr ms my nb nl oc pa pl pt pt_BR ro ru si_LK sk sl sr sr@latin sv te tr tr_TR uk uz vi zh_CN zh_TW"
inherit cmake flag-o-matic plocale virtualx xdg
MY_P="${P/_}"
if [[ ${PV} == *9999* ]]; then
EGIT_REPO_URI="https://github.com/clementine-player/Clementine.git"
inherit git-r3
else
S="${WORKDIR}/${P/_}"
SRC_URI_BASE="https://github.com/clementine-player/${PN^}"
COMMIT=""
if [[ -n "${COMMIT}" ]] ; then
SRC_URI="${SRC_URI_BASE}/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}/${PN^}-${COMMIT}"
elif [[ $(ver_cut 3) -gt 90 ]] ; then
SRC_URI="${SRC_URI_BASE}/archive/${PV}.tar.gz -> ${P}.tar.gz"
else
SRC_URI="${SRC_URI_BASE}/releases/download/${PV/_}/${P/_}.tar.xz"
fi
KEYWORDS="~amd64 ~x86"
fi
DESCRIPTION="Modern music player and library organizer based on Amarok 1.4 and Qt"
HOMEPAGE="https://www.clementine-player.org https://github.com/clementine-player/Clementine"
LICENSE="GPL-3"
SLOT="0"
IUSE="box cdda +dbus debug dropbox googledrive ipod lastfm mms moodbar mtp projectm pulseaudio seafile skydrive test +udisks wiimote"
RESTRICT="!test? ( test )"
REQUIRED_USE="
udisks? ( dbus )
wiimote? ( dbus )
"
BDEPEND="
>=dev-cpp/gtest-1.8.0
dev-qt/linguist-tools:5
sys-devel/gettext
virtual/pkgconfig
test? (
dev-qt/qttest:5
gnome-base/gsettings-desktop-schemas
)
"
COMMON_DEPEND="
app-crypt/qca:2[qt5(+)]
dev-db/sqlite:=
dev-libs/crypto++:=
dev-libs/glib:2
dev-libs/libxml2
dev-libs/protobuf:=
dev-qt/qtconcurrent:5
dev-qt/qtcore:5
dev-qt/qtgui:5
dev-qt/qtnetwork:5[ssl]
dev-qt/qtsql:5[sqlite]
dev-qt/qtwidgets:5
media-libs/chromaprint:=
media-libs/gstreamer:1.0
media-libs/gst-plugins-base:1.0
>=media-libs/libmygpo-qt-1.0.9[qt5(+)]
>=media-libs/taglib-1.11.1_p20181028
sys-libs/zlib
virtual/glu
x11-libs/libX11
cdda? ( dev-libs/libcdio:= )
dbus? ( dev-qt/qtdbus:5 )
ipod? ( >=media-libs/libgpod-0.8.0 )
lastfm? ( >=media-libs/liblastfm-1.1.0_pre20150206 )
moodbar? ( sci-libs/fftw:3.0 )
mtp? ( >=media-libs/libmtp-1.0.0 )
projectm? (
media-libs/glew:=
>=media-libs/libprojectm-1.2.0:=
virtual/opengl
)
"
RDEPEND="${COMMON_DEPEND}
media-plugins/gst-plugins-meta:1.0
media-plugins/gst-plugins-soup:1.0
media-plugins/gst-plugins-taglib:1.0
mms? ( media-plugins/gst-plugins-libmms:1.0 )
mtp? ( gnome-base/gvfs[mtp] )
udisks? ( sys-fs/udisks:2 )
"
DEPEND="${COMMON_DEPEND}
dev-libs/boost
dev-qt/qtopengl:5
dev-qt/qtx11extras:5
dev-qt/qtxml:5
box? ( dev-cpp/sparsehash )
dropbox? ( dev-cpp/sparsehash )
googledrive? ( dev-cpp/sparsehash )
pulseaudio? ( media-sound/pulseaudio )
seafile? ( dev-cpp/sparsehash )
skydrive? ( dev-cpp/sparsehash )
"
DOCS=( Changelog README.md )
src_prepare() {
plocale_find_changes "src/translations" "" ".po"
cmake_src_prepare
# some tests fail or hang
sed -i \
-e '/add_test_file(translations_test.cpp/d' \
tests/CMakeLists.txt || die
if ! use test; then
sed -e "/find_package.*Qt5/s:\ Test::" -i CMakeLists.txt || die
cmake_comment_add_subdirectory tests
fi
rm -r 3rdparty/{libmygpo-qt,libmygpo-qt5,taglib} || die
}
src_configure() {
# spotify is not in portage
local mycmakeargs=(
-DBUILD_WERROR=OFF
# force to find crypto++ see bug #548544
-DCRYPTOPP_LIBRARIES="cryptopp"
-DCRYPTOPP_FOUND=ON
# avoid automagically enabling of ccache (bug #611010)
-DCCACHE_EXECUTABLE=OFF
-DENABLE_BREAKPAD=OFF #< disable crash reporting
-DENABLE_DEVICEKIT=OFF
-DENABLE_GIO=ON
-DENABLE_SPOTIFY_BLOB=OFF
-DUSE_SYSTEM_GMOCK=ON
-DUSE_SYSTEM_PROJECTM=ON
-DBUNDLE_PROJECTM_PRESETS=OFF
-DLINGUAS="$(plocale_get_locales)"
-DENABLE_BOX="$(usex box)"
-DENABLE_AUDIOCD="$(usex cdda)"
-DCMAKE_DISABLE_FIND_PACKAGE_Qt5DBus=$(usex !dbus)
-DENABLE_DROPBOX="$(usex dropbox)"
-DENABLE_GOOGLE_DRIVE="$(usex googledrive)"
-DENABLE_LIBGPOD="$(usex ipod)"
-DENABLE_LIBLASTFM="$(usex lastfm)"
-DENABLE_MOODBAR="$(usex moodbar)"
-DENABLE_LIBMTP="$(usex mtp)"
-DENABLE_VISUALISATIONS="$(usex projectm)"
-DENABLE_SEAFILE="$(usex seafile)"
-DENABLE_SKYDRIVE="$(usex skydrive)"
-DENABLE_LIBPULSE="$(usex pulseaudio)"
-DENABLE_UDISKS2="$(usex udisks)"
-DENABLE_WIIMOTEDEV="$(usex wiimote)"
)
use !debug && append-cppflags -DQT_NO_DEBUG_OUTPUT
cmake_src_configure
}
src_test() {
cd "${CMAKE_BUILD_DIR}" || die
virtx emake test
}
pkg_postinst() {
xdg_pkg_postinst
elog "Note that list of supported formats is controlled by media-plugins/gst-plugins-meta "
elog "USE flags. You may be interested in setting aac, flac, mp3, ogg or wavpack USE flags "
elog "depending on your preferences"
}
|
GitWeb