blob: 0008c65db77538fe1f8bc6436439bce682bf6739 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{10..12} )
inherit python-r1
DESCRIPTION="Versatile replacement for vmstat, iostat and ifstat"
HOMEPAGE="http://dag.wieers.com/home-made/dstat/"
SRC_URI="https://github.com/dagwieers/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="~alpha amd64 ~arm64 ~hppa ~ia64 ~mips ppc ppc64 sparc x86 ~x86-linux"
IUSE="doc examples"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
RDEPEND="${PYTHON_DEPS}
dev-python/six[${PYTHON_USEDEP}]"
DEPEND="${RDEPEND}"
PATCHES=(
"${FILESDIR}/dstat-${PV}-skip-non-sandbox-tests.patch"
"${FILESDIR}/fix-collections-deprecation-warning.patch"
"${FILESDIR}/dstat-0.7.4-fix-csv-output.patch"
"${FILESDIR}/dstat-${PV}-fix-backslash-in-regex.patch"
)
src_prepare() {
# bug fix: allow delay to be specified
# backport from: https://github.com/dagwieers/dstat/pull/167/files
sed -e 's; / op\.delay; // op.delay;' -i "dstat" || die
default
}
src_test() {
python_foreach_impl emake test
}
src_install() {
python_foreach_impl python_doscript dstat
insinto /usr/share/dstat
newins dstat dstat.py
doins plugins/dstat_*.py
doman docs/dstat.1
einstalldocs
if use examples; then
dodoc examples/{mstat,read}.py
fi
if use doc; then
dodoc docs/*.html
fi
}
|
GitWeb
