blob: 9bb97ede3a44af6a8e8b2fedc02e9cb28bb712d8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit flag-o-matic toolchain-funcs
DESCRIPTION="GPT partition table manipulator for Linux"
HOMEPAGE="https://www.rodsbooks.com/gdisk/"
SRC_URI="https://downloads.sourceforge.net/${PN}/${PN}/${PV}/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~loong ~mips ppc ppc64 ~riscv sparc x86 ~amd64-linux ~x86-linux"
IUSE="ncurses static"
# libuuid from util-linux is required.
RDEPEND="!static? (
dev-libs/popt
ncurses? ( sys-libs/ncurses:=[unicode(+)] )
kernel_linux? ( sys-apps/util-linux )
)"
DEPEND="
${RDEPEND}
static? (
dev-libs/popt[static-libs(+)]
ncurses? ( sys-libs/ncurses:=[unicode(+),static-libs(+)] )
kernel_linux? ( sys-apps/util-linux[static-libs(+)] )
)
virtual/pkgconfig
"
PATCHES=(
"${FILESDIR}/${PN}-1.0.9-libuuid.patch" #844073
"${FILESDIR}/${PN}-1.0.9-popt_segv.patch" #872131
"${FILESDIR}"/${PN}-1.0.9-build_flags.patch
"${FILESDIR}"/${PN}-1.0.9-musl-1.2.4.patch
)
src_prepare() {
default
tc-export CXX PKG_CONFIG
if ! use ncurses ; then
sed -i \
-e '/^all:/s: cgdisk::' \
Makefile || die
fi
sed \
-e '/g++/s:=:?=:g' \
-e 's:-lncursesw:$(shell $(PKG_CONFIG) --libs ncursesw):g' \
-i Makefile || die
use static && append-ldflags -static
}
src_install() {
dosbin gdisk sgdisk $(usex ncurses cgdisk '') fixparts
doman *.8
dodoc NEWS README
}
|
GitWeb
