blob: c81f292bc9d13ede4ef4a74a08d1664cf96e8993 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit bash-completion-r1 optfeature udev
DESCRIPTION="OpenVZ ConTainers control utility"
HOMEPAGE="https://openvz.org/"
SRC_URI="https://download.openvz.org/utils/${PN}/${PV}/src/${P}.tar.bz2"
LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="amd64 ~ppc64 x86"
IUSE="+ploop +vzmigrate"
BDEPEND="virtual/pkgconfig"
RDEPEND="
>=dev-libs/libcgroup-0.38
net-firewall/iptables
sys-apps/attr
sys-apps/ed
>=sys-apps/iproute2-3.3.0
>=sys-fs/vzquota-3.1
virtual/udev
ploop? (
dev-libs/libxml2
sys-block/parted
>=sys-cluster/ploop-1.13
sys-fs/quota
)
vzmigrate? (
app-arch/tar[xattr,acl]
net-misc/openssh
net-misc/rsync[xattr,acl]
net-misc/bridge-utils
virtual/awk
)
"
DEPEND="${RDEPEND}"
PATCHES=(
"${FILESDIR}"/${P}-glibc225.patch
"${FILESDIR}"/${P}-glibc225-2.patch
)
src_prepare() {
# Set default OSTEMPLATE on gentoo
sed -i -e 's:=redhat-:=gentoo-:' etc/dists/default || die 'sed on etc/dists/default failed'
# Set proper udev directory
sed -i -e "s:/lib/udev:$(get_udevdir):" src/lib/dev.c || die 'sed on src/lib/dev.c failed'
default
}
src_configure() {
econf \
--localstatedir=/var \
--enable-udev \
--enable-bashcomp \
--enable-logrotate \
--with-vz \
$(use_with ploop) \
--with-cgroup
}
src_install() {
emake DESTDIR="${D}" udevdir="$(get_udevdir)"/rules.d install install-gentoo
# install the bash-completion script into the right location
rm -rf "${ED}"/etc/bash_completion.d || die
newbashcomp etc/bash_completion.d/vzctl.sh ${PN}
# We need to keep some dirs
keepdir /vz/{dump,lock,root,private,template/cache}
keepdir /etc/vz/names /var/lib/vzctl/veip
}
pkg_postinst() {
einfo "This vzctl release requires a kernel above 2.6.32.92"
optfeature "Checkpoint suspend/restore support (experimental)" sys-process/criu
optfeature "Compressed .xz templates" app-arch/xz-utils
optfeature "Signed templates" app-crypt/gnupg
}
|
GitWeb