blob: 2997ce0cf204b37acf2d1e0b55d87fe38f9d04ed (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{10..12} )
inherit flag-o-matic meson-multilib udev python-any-r1
DESCRIPTION="An interface for filesystems implemented in userspace"
HOMEPAGE="https://github.com/libfuse/libfuse"
SRC_URI="https://github.com/libfuse/libfuse/releases/download/${P}/${P}.tar.gz"
LICENSE="GPL-2 LGPL-2.1"
SLOT="3"
KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86"
IUSE="+suid test"
RESTRICT="test"
PROPERTIES="test_privileged"
BDEPEND="
virtual/pkgconfig
test? (
${PYTHON_DEPS}
$(python_gen_any_dep 'dev-python/pytest[${PYTHON_USEDEP}]')
$(python_gen_any_dep 'dev-python/looseversion[${PYTHON_USEDEP}]')
)
"
RDEPEND=">=sys-fs/fuse-common-3.3.0-r1"
DOCS=( AUTHORS ChangeLog.rst README.md doc/README.NFS doc/kernel.txt )
python_check_deps() {
python_has_version "dev-python/pytest[${PYTHON_USEDEP}]" &&
python_has_version "dev-python/looseversion[${PYTHON_USEDEP}]"
}
pkg_setup() {
use test && python-any-r1_pkg_setup
}
multilib_src_configure() {
# bug #853058
filter-lto
local emesonargs=(
$(meson_use test examples)
$(meson_use test tests)
-Duseroot=false
-Dinitscriptdir=
-Dudevrulesdir="${EPREFIX}$(get_udevdir)/rules.d"
)
meson_src_configure
}
src_test() {
# For tests to pass:
# sandbox must be disabled.
# Write access to /dev/cuse* and /dev/fuse is required.
# root must be a member of the portage group; CAP_DAC_OVERRIDE is dropped.
# TMPDIR must be short for unix socket paths.
local -x TMPDIR=/tmp
multilib-minimal_src_test
}
multilib_src_test() {
epytest
}
multilib_src_install_all() {
# Installed via fuse-common
rm -r "${ED}"{/etc,$(get_udevdir)} || die
# useroot=false prevents the build system from doing this.
use suid && fperms u+s /usr/bin/fusermount3
# manually install man pages to respect compression
rm -r "${ED}"/usr/share/man || die
doman doc/{fusermount3.1,mount.fuse3.8}
}
|
GitWeb