blob: 40bd0326562e0ee518e62674b7b5fb793961d538 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit autotools
DESCRIPTION="ext2fs and minix disk editor for linux"
HOMEPAGE="http://lde.sourceforge.net/"
SRC_URI="https://downloads.sourceforge.net/lde/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
RDEPEND="sys-libs/ncurses:0="
DEPEND="${RDEPEND}"
BDEPEND="
virtual/pkgconfig
app-alternatives/yacc
"
S="${WORKDIR}/${PN}"
PATCHES=(
"${FILESDIR}/${P}-no-shadowing.patch"
"${FILESDIR}/${P}-fno-common.patch"
"${FILESDIR}/${P}-tinfo.patch"
"${FILESDIR}/${P}-respect-ar.patch"
)
DOCS=( WARNING README TODO COPYING )
RESTRICT="test"
src_prepare() {
default
# Remove prebuilt lde binary (so that failures to compile are fatal!)
# bug #776862
rm lde || die
cd macros || die
# bug #775968 again
touch ar-lib install-sh || die
mv configure.{in,ac} || die
eautoreconf
}
src_install() {
dosbin "${PN}"
newman "doc/${PN}.man" "${PN}.8"
einstalldocs
}
|
GitWeb
