blob: 16457c2bda8942da796b68cad8662b6f08c38555 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_8 python3_9 python3_10 )
inherit python-single-r1 udev
MY_P="${PN}-v${PV}"
DESCRIPTION="Replacement for xbacklight that uses the ACPI interface to set brightness"
HOMEPAGE="https://gitlab.com/wavexx/acpilight/"
SRC_URI="https://gitlab.com/wavexx/acpilight/-/archive/v${PV}/${MY_P}.tar.gz"
LICENSE="GPL-3+"
SLOT="0"
KEYWORDS="amd64 x86"
IUSE=""
S="${WORKDIR}/${MY_P}"
RDEPEND="virtual/udev
acct-group/video
!dev-libs/light
${PYTHON_DEPS}
!x11-apps/xbacklight"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
DOCS=( README.rst NEWS.rst )
PATCHES=( "${FILESDIR}/acpilight-1.2-fix-log10-of-zero.patch" )
# Disable Makefile that installs by default
src_compile() { :; }
src_install() {
python_doscript xbacklight
udev_dorules "${S}"/90-backlight.rules
doman xbacklight.1
einstalldocs
newinitd "${FILESDIR}"/acpilight.initd acpilight
newconfd "${FILESDIR}"/acpilight.confd acpilight
}
pkg_postinst() {
udev_reload
einfo
elog "To use the xbacklight binary as a regular user, you must be a part of the video group"
einfo
elog "If this utility does not find any backlights to manipulate,"
elog "verify you have kernel support on the device and display driver enabled."
einfo
elog "To take advantage of the OpenRC init script, and automate the process of"
elog "saving and restoring the brightness level you should add acpilight"
elog "to the boot runlevel. You can do this as root like so:"
elog "# rc-update add acpilight boot"
einfo
}
pkg_postrm() {
# Triggers a QA warning if missing
udev_reload
}
|
GitWeb
