blob: 24417459a815ed9613edbb1c0c9479d31be06196 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{10..13} )
inherit flag-o-matic gnome.org meson python-any-r1 vala xdg
DESCRIPTION="Library providing a virtual terminal emulator widget"
HOMEPAGE="https://gitlab.gnome.org/GNOME/vte/"
# Upstream is hostile and refuses to upload tarballs.
SRC_URI="https://gitlab.gnome.org/GNOME/${PN}/-/archive/${PV}/${P}.tar.bz2"
SRC_URI="${SRC_URI}
!vanilla? (
https://dev.gentoo.org/~pacho/${PN}/${P}-command-notify.patch.xz
https://dev.gentoo.org/~pacho/${PN}/${P}-a11y-implement-GtkAccessibleText.patch.xz )
"
# Once SIXEL support ships (0.66 or later), might need xterm license (but code might be considered upgraded to LGPL-3+)
LICENSE="LGPL-3+ GPL-3+"
SLOT="2.91" # vte_api_version in meson.build
KEYWORDS="~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
IUSE="+crypt debug gtk-doc +icu +introspection systemd +vala vanilla"
REQUIRED_USE="
gtk-doc? ( introspection )
vala? ( introspection )
"
DEPEND="
>=x11-libs/gtk+-3.24.22:3[introspection?]
>=x11-libs/cairo-1.0
>=dev-libs/fribidi-1.0.0
>=dev-libs/glib-2.72:2
crypt? ( >=net-libs/gnutls-3.2.7:0= )
icu? ( dev-libs/icu:= )
>=x11-libs/pango-1.22.0
>=dev-libs/libpcre2-10.21:=
systemd? ( >=sys-apps/systemd-220:= )
>=app-arch/lz4-1.9
introspection? ( >=dev-libs/gobject-introspection-1.56:= )
x11-libs/pango[introspection?]
"
RDEPEND="${DEPEND}
~gui-libs/vte-common-${PV}[systemd?]
"
BDEPEND="
${PYTHON_DEPS}
dev-libs/libxml2:2
dev-util/glib-utils
gtk-doc? ( dev-util/gi-docgen )
>=sys-devel/gettext-0.19.8
virtual/pkgconfig
vala? ( $(vala_depend) )
"
PATCHES=( "${FILESDIR}/${PN}-0.76.3-stdint.patch" )
src_prepare() {
default
use vala && vala_setup
xdg_environment_reset
use elibc_musl && eapply "${FILESDIR}"/${PN}-0.66.2-musl-W_EXITCODE.patch
if ! use vanilla; then
# From https://src.fedoraproject.org/rpms/vte291/raw/f40/f/0001-add-notification-and-shell-precmd-preexec.patch
# Adds OSC 777 support for desktop notifications in gnome-terminal or elsewhere
eapply "${WORKDIR}"/${P}-command-notify.patch
# From https://src.fedoraproject.org/rpms/vte291/raw/f40/f/0001-a11y-implement-GtkAccessibleText.patch
# Migrate to GTK4 and add VteTerminal:enable-a11y feature flag
eapply "${WORKDIR}"/${P}-a11y-implement-GtkAccessibleText.patch
fi
# -Ddebugg option enables various debug support via VTE_DEBUG, but also ggdb3; strip the latter
sed -e '/ggdb3/d' -i meson.build || die
sed -i 's/vte_gettext_domain = vte_api_name/vte_gettext_domain = vte_gtk3_api_name/' meson.build || die
}
src_configure() {
# Upstream don't support LTO & error out on it in meson.build
filter-lto
local emesonargs=(
-Da11y=true
$(meson_use debug)
$(meson_use gtk-doc docs)
$(meson_use introspection gir)
-Dfribidi=true # pulled in by pango anyhow
-Dglade=true
$(meson_use crypt gnutls)
-Dgtk3=true
-Dgtk4=false
$(meson_use icu)
$(meson_use systemd _systemd)
$(meson_use vala vapi)
)
meson_src_configure
}
src_install() {
# not meson_src_install because this would include einstalldocs, which
# would result in file collisions with gui-libs/vte
meson_install
# Remove files that are provided by gui-libs/vte-common
rm "${ED}"/usr/libexec/vte-urlencode-cwd || die
rm "${ED}"/etc/profile.d/vte.sh || die
rm "${ED}"/etc/profile.d/vte.csh || die
if use systemd; then
rm "${ED}"/usr/lib/systemd/user/vte-spawn-.scope.d/defaults.conf || die
fi
if use gtk-doc; then
mkdir -p "${ED}"/usr/share/gtk-doc/ || die
mv "${ED}"/usr/share/doc/vte-${SLOT} "${ED}"/usr/share/gtk-doc/vte-${SLOT}-gtk3 || die
fi
}
|
GitWeb