blob: c2619c850ccb79082b2cae621b0a3ee166a1d677 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
|
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
PLOCALES="
bs ca cs da de el es_AR es_CO es fr hu it ja nl no pl pt_BR pt_PT ru sv tr
zh_CN zh_TW
"
inherit autotools eutils l10n
DESCRIPTION="MS-Explorer-like minimalist file manager for X"
HOMEPAGE="http://roland65.free.fr/xfe"
SRC_URI="mirror://sourceforge/${PN}/${PN}/${PV}/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="debug nls startup-notification"
RDEPEND="
media-libs/libpng:0
x11-libs/fox:1.6[png,truetype]
x11-libs/libX11
x11-libs/libXft
startup-notification? ( x11-libs/startup-notification )
"
DEPEND="
${RDEPEND}
virtual/pkgconfig
nls? (
dev-util/intltool
sys-devel/gettext
)
"
DOCS=( AUTHORS BUGS ChangeLog README TODO )
PATCHES=( "${FILESDIR}/${PN}-1.42-use_pkgconfig_for_freetype_and_xft.patch" )
src_prepare() {
default
cat >po/POTFILES.skip <<-EOF
src/icons.cpp
xfe.desktop.in.in
xfi.desktop.in.in
xfp.desktop.in.in
xfv.desktop.in.in
xfw.desktop.in.in
EOF
# malformed LINGUAS file
# recent intltool expects newline for every linguas
sed -i \
-e '/^#/!s:\s\s*:\n:g' \
po/LINGUAS || die
# remove not selected locales
rm_locale() { sed -i -e "/${1}/d" po/LINGUAS || die ;}
l10n_for_each_disabled_locale_do rm_locale
sed -i \
-e 's|AM_CONFIG_HEADER|AC_CONFIG_HEADERS|g' \
configure.ac || die
eautoreconf
}
src_configure() {
local myeconfargs=(
$(use_enable debug)
$(use_enable nls)
$(use_enable startup-notification sn)
--enable-minimalflags
)
econf "${myeconfargs[@]}"
}
|
GitWeb