blob: 01ec69226dafee55f6c133a8bd0c979f2a84598d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_{6,7,8,9} )
DISTUTILS_SINGLE_IMPL=yes
DISTUTILS_USE_SETUPTOOLS=no
inherit xdg distutils-r1 tmpfiles prefix
MY_P="${PN}-${PV%_p*}"
DESCRIPTION="X Persistent Remote Apps (xpra) and Partitioning WM (parti) based on wimpiggy"
HOMEPAGE="https://xpra.org/"
SRC_URI="https://xpra.org/src/${MY_P}.tar.xz"
LICENSE="GPL-2 BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="brotli +client +clipboard csc cups dbus ffmpeg jpeg +lz4 lzo minimal opengl pillow pulseaudio server sound test vpx webcam webp"
REQUIRED_USE="${PYTHON_REQUIRED_USE}
|| ( client server )
cups? ( dbus )
opengl? ( client )
"
DEPEND="
${PYTHON_DEPS}
$(python_gen_cond_dep '
dev-python/pygobject:3[${PYTHON_USEDEP},cairo]
opengl? ( dev-python/pyopengl[${PYTHON_USEDEP}] )
sound? ( dev-python/gst-python:1.0[${PYTHON_USEDEP}] )
')
x11-libs/gtk+:3[introspection]
x11-libs/libX11
x11-libs/libXcomposite
x11-libs/libXdamage
x11-libs/libXfixes
x11-libs/libXrandr
x11-libs/libXtst
x11-libs/libxkbfile
brotli? ( app-arch/brotli )
csc? ( >=media-video/ffmpeg-1.2.2:0= )
ffmpeg? ( >=media-video/ffmpeg-3.2.2:0=[x264,x265] )
jpeg? ( media-libs/libjpeg-turbo )
pulseaudio? (
media-sound/pulseaudio
media-plugins/gst-plugins-pulse:1.0
)
sound? (
media-libs/gstreamer:1.0
media-libs/gst-plugins-base:1.0
)
vpx? ( media-libs/libvpx media-video/ffmpeg )
webp? ( media-libs/libwebp )
"
RDEPEND="
${DEPEND}
$(python_gen_cond_dep '
dev-python/netifaces[${PYTHON_USEDEP}]
dev-python/rencode[${PYTHON_USEDEP}]
dev-python/pillow[jpeg?,${PYTHON_USEDEP}]
cups? ( dev-python/pycups[${PYTHON_USEDEP}] )
dbus? ( dev-python/dbus-python[${PYTHON_USEDEP}] )
lz4? ( dev-python/lz4[${PYTHON_USEDEP}] )
lzo? ( >=dev-python/python-lzo-0.7.0[${PYTHON_USEDEP}] )
opengl? (
client? ( dev-python/pyopengl_accelerate[${PYTHON_USEDEP}] )
)
webcam? (
dev-python/numpy[${PYTHON_USEDEP}]
dev-python/pyinotify[${PYTHON_USEDEP}]
media-libs/opencv[${PYTHON_USEDEP},python]
)
')
acct-group/xpra
virtual/ssh
x11-apps/xmodmap
server? (
x11-base/xorg-server[-minimal,xvfb]
x11-drivers/xf86-input-void
)
"
BDEPEND="
virtual/pkgconfig
$(python_gen_cond_dep '
>=dev-python/cython-0.16[${PYTHON_USEDEP}]
')
"
RESTRICT="!test? ( test )"
PATCHES=(
"${FILESDIR}"/${PN}-3.0.2_ignore-gentoo-no-compile.patch
"${FILESDIR}"/${PN}-3.0.2-ldconfig.patch
"${FILESDIR}"/${PN}-4.0.3-suid-warning.patch
"${FILESDIR}"/${PN}-4.0.6-r28363.patch
)
S="${WORKDIR}/${MY_P}"
pkg_postinst() {
tmpfiles_process /usr/lib/tmpfiles.d/xpra.conf
xdg_pkg_postinst
}
python_prepare_all() {
hprefixify -w '/os.path/' setup.py
hprefixify tmpfiles.d/xpra.conf xpra/server/server_util.py \
xpra/platform{/xposix,}/paths.py xpra/scripts/server.py
if use minimal; then
sed -r -e 's/^(pam|scripts|xdg_open)_ENABLED.*/\1_ENABLED=False/' \
-i setup.py || die
fi
distutils-r1_python_prepare_all
}
python_configure_all() {
sed -e "/'pulseaudio'/s:DEFAULT_PULSEAUDIO:$(usex pulseaudio True False):" \
-i setup.py || die
mydistutilsargs=(
--without-PIC
--without-Xdummy
$(use_with client)
$(use_with clipboard)
$(use_with csc csc_swscale)
--without-csc_libyuv
--without-cuda_rebuild
--without-cuda_kernels
$(use_with cups printing)
--without-debug
$(use_with dbus)
$(use_with ffmpeg dec_avcodec2)
$(use_with ffmpeg enc_ffmpeg)
$(use_with ffmpeg enc_x264)
$(use_with ffmpeg enc_x265)
--with-gtk3
--without-html5
$(use_with jpeg jpeg_encoder)
$(use_with jpeg jpeg_decoder)
--without-mdns
--without-minify
$(use_with opengl)
$(use_with server shadow)
$(use_with server)
$(use_with sound)
--with-strict
$(use_with vpx)
--with-warn
$(use_with webcam)
$(use_with webp)
--with-x11
)
export XPRA_SOCKET_DIRS="${EPREFIX}/run/xpra"
}
|
GitWeb