Initial commit, ebuild written by me.

Package-Manager: portage-2.1.9.46/cvs/Linux x86_64

10 files changed, 218 insertions, 0 deletions

diff --git a/app-emulation/libvirt-snmp/ChangeLog b/app-emulation/libvirt-snmp/ChangeLog
new file mode 100644
index 000000000000..9eb8da6b9ca0
--- /dev/null
+++ b/app-emulation/libvirt-snmp/ChangeLog
@@ -0,0 +1,11 @@
+# ChangeLog for app-emulation/libvirt-snmp
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt-snmp/ChangeLog,v 1.1 2011/05/11 08:57:32 dev-zero Exp $
+
+*libvirt-snmp-0.0.2 (11 May 2011)
+
+  11 May 2011; Tiziano Müller <dev-zero@gentoo.org>
+  +libvirt-snmp-0.0.2.ebuild, +files/libvirt-snmp.confd,
+  +files/libvirt-snmp.initd, +metadata.xml:
+  Initial commit, ebuild written by me.
+
diff --git a/app-emulation/libvirt-snmp/files/libvirt-snmp.confd b/app-emulation/libvirt-snmp/files/libvirt-snmp.confd
new file mode 100644
index 000000000000..f1685bb5e9d9
--- /dev/null
+++ b/app-emulation/libvirt-snmp/files/libvirt-snmp.confd
@@ -0,0 +1,6 @@
+
+# Specify the URI where your libvirt instance is listening
+LIBVIRT_DEFAULT_URI="qemu:///system"
+
+# additional options
+LIBVIRT_SNMP_OPTIONS=""
diff --git a/app-emulation/libvirt-snmp/files/libvirt-snmp.initd b/app-emulation/libvirt-snmp/files/libvirt-snmp.initd
new file mode 100644
index 000000000000..c8c5020f2c9b
--- /dev/null
+++ b/app-emulation/libvirt-snmp/files/libvirt-snmp.initd
@@ -0,0 +1,26 @@
+#!/sbin/runscript
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt-snmp/files/libvirt-snmp.initd,v 1.1 2011/05/11 08:57:32 dev-zero Exp $
+
+depend() {
+    need snmpd
+    use snmptrapd
+    use libvirtd
+}
+
+start() {
+    ebegin "Starting libvirt subagent"
+    start-stop-daemon --start \
+        --env LIBVIRT_DEFAULT_URI="${LIBVIRT_DEFAULT_URI}" \
+        --exec /usr/bin/libvirtMib_subagent \
+        -- ${LIBVIRT_SNMP_OPTIONS}
+    eend $?
+}
+
+stop() {
+    ebegin "Stopping libvirt subagent"
+    start-stop-daemon --stop \
+        --exec /usr/bin/libvirtMib_subagent
+    eend $?
+}
diff --git a/app-emulation/libvirt-snmp/libvirt-snmp-0.0.2.ebuild b/app-emulation/libvirt-snmp/libvirt-snmp-0.0.2.ebuild
new file mode 100644
index 000000000000..fd91c396ec31
--- /dev/null
+++ b/app-emulation/libvirt-snmp/libvirt-snmp-0.0.2.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt-snmp/libvirt-snmp-0.0.2.ebuild,v 1.1 2011/05/11 08:57:32 dev-zero Exp $
+
+EAPI=4
+
+DESCRIPTION="Provides SNMP functionality for libvirt."
+HOMEPAGE="http://libvirt.org"
+SRC_URI="http://www.libvirt.org/sources/snmp/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE=""
+
+RDEPEND="app-emulation/libvirt
+	net-analyzer/net-snmp"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+
+src_install() {
+	default
+	newinitd "${FILESDIR}/libvirt-snmp.initd" "${PN}"
+	newconfd "${FILESDIR}/libvirt-snmp.confd" "${PN}"
+}
+
+pkg_postinst() {
+	elog "This daemon runs as an AgentX sub-daemon for snmpd. You should therefore"
+	elog "enable the AgentX functionality in snmpd by specifying the following"
+	elog "in /etc/snmp/snmpd.conf:"
+	elog "  master agentx"
+	elog "It is further recommended to send traps to the localhost as well using"
+	elog "this option:"
+	elog "  trap2sink localhost"
+	elog "More information is available here:"
+	elog "  http://wiki.libvirt.org/page/Libvirt-snmp"
+}
diff --git a/app-emulation/libvirt-snmp/metadata.xml b/app-emulation/libvirt-snmp/metadata.xml
new file mode 100644
index 000000000000..9f8438a7910f
--- /dev/null
+++ b/app-emulation/libvirt-snmp/metadata.xml
@@ -0,0 +1,9 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <herd>no-herd</herd>
+  <maintainer>
+    <email>dev-zero@gentoo.org</email>
+    <name>Tiziano Müller</name>
+  </maintainer>
+</pkgmetadata>
diff --git a/app-emulation/spice-vdagent/ChangeLog b/app-emulation/spice-vdagent/ChangeLog
new file mode 100644
index 000000000000..93a23bf47bde
--- /dev/null
+++ b/app-emulation/spice-vdagent/ChangeLog
@@ -0,0 +1,11 @@
+# ChangeLog for app-emulation/spice-vdagent
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/spice-vdagent/ChangeLog,v 1.1 2011/05/11 09:02:31 dev-zero Exp $
+
+*spice-vdagent-0.8.0 (11 May 2011)
+
+  11 May 2011; Tiziano Müller <dev-zero@gentoo.org>
+  +spice-vdagent-0.8.0.ebuild, +files/spice-vdagent.confd,
+  +files/spice-vdagent.initd, +metadata.xml:
+  Initial commit, ebuild written by me.
+
diff --git a/app-emulation/spice-vdagent/files/spice-vdagent.confd b/app-emulation/spice-vdagent/files/spice-vdagent.confd
new file mode 100644
index 000000000000..326f894424d7
--- /dev/null
+++ b/app-emulation/spice-vdagent/files/spice-vdagent.confd
@@ -0,0 +1,7 @@
+
+# The virtual communication port provided by the hypervisor/vm
+PORT="/dev/virtio-ports/com.redhat.spice.0"
+
+# extra arguments for spice-vdagentd
+SPICE_VDAGENT_ARGS=""
+
diff --git a/app-emulation/spice-vdagent/files/spice-vdagent.initd b/app-emulation/spice-vdagent/files/spice-vdagent.initd
new file mode 100644
index 000000000000..3d8f71ab00d9
--- /dev/null
+++ b/app-emulation/spice-vdagent/files/spice-vdagent.initd
@@ -0,0 +1,47 @@
+#!/sbin/runscript
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/spice-vdagent/files/spice-vdagent.initd,v 1.1 2011/05/11 09:02:31 dev-zero Exp $
+
+depend() {
+    after dbus
+}
+
+PIDFILE="/var/run/spice-vdagentd/spice-vdagentd.pid"
+
+start() {
+    ebegin "Checking for required modules and devices"
+
+    if [[ ! -d /sys/module/uinput ]] ; then
+        eerror "Module 'uinput' not loaded or not enabled in the kernel"
+        eend 1
+        return 1
+    fi
+
+    if [[ ! -c "${PORT}" ]] ; then
+        eerror "Required virtio port does not exist. Make sure you"
+        eerror "started the virtual machine with appropriate parameters."
+        eend 1
+        return 1
+    fi
+    eend 0
+
+    # cleanup stalled socket
+    rm -f /var/run/spice-vdagentd/spice-vdagent-sock
+
+    ebegin "Starting spice VD agent daemon"
+    start-stop-daemon
+        --start \
+        --pidfile "${PIDFILE}" \
+        --exec /usr/sbin/spice-vdagentd \
+        -- ${SPICE_VDAGENT_ARGS}
+    eend $?
+}
+
+stop() {
+    ebegin "Stopping spice VD agent daemon"
+    start-stop-daemon
+        --stop \
+        --pidfile "${PIDFILE}"
+    eend $?
+}
diff --git a/app-emulation/spice-vdagent/metadata.xml b/app-emulation/spice-vdagent/metadata.xml
new file mode 100644
index 000000000000..91aa5bfaed72
--- /dev/null
+++ b/app-emulation/spice-vdagent/metadata.xml
@@ -0,0 +1,14 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<herd>no-herd</herd>
+	<maintainer>
+		<email>dev-zero@gentoo.org</email>
+		<name>Tiziano Müller</name>
+	</maintainer>
+	<use>
+		<flag name="consolekit">Use <pkg>sys-auth/consolekit</pkg> to determine the
+			master vdagentd in case of multiple running vdagentds (highly
+			recommended)</flag>
+	</use>
+</pkgmetadata>
diff --git a/app-emulation/spice-vdagent/spice-vdagent-0.8.0.ebuild b/app-emulation/spice-vdagent/spice-vdagent-0.8.0.ebuild
new file mode 100644
index 000000000000..437f8a65c030
--- /dev/null
+++ b/app-emulation/spice-vdagent/spice-vdagent-0.8.0.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/spice-vdagent/spice-vdagent-0.8.0.ebuild,v 1.1 2011/05/11 09:02:31 dev-zero Exp $
+
+EAPI=4
+
+inherit linux-info
+
+DESCRIPTION="SPICE VD Linux Guest Agent."
+HOMEPAGE="http://spice-space.org/"
+SRC_URI="http://spice-space.org/download/releases/${P}.tar.bz2"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+consolekit"
+
+RDEPEND="x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/libX11
+	>=app-emulation/spice-protocol-0.8.0
+	consolekit? ( sys-auth/consolekit sys-apps/dbus )"
+DEPEND="dev-util/pkgconfig
+	${RDEPEND}"
+
+CONFIG_CHECK="INPUT_UINPUT"
+ERROR_INPUT_UINPUT="User level driver support is required to run the spice-vdagent daemon"
+
+src_configure() {
+	econf \
+		--localstatedir=/var \
+		$(use_enable consolekit console-kit)
+}
+
+src_install() {
+	default
+
+	rm -rf "${D}"/etc/{rc,tmpfiles}.d
+
+	keepdir /var/run/spice-vdagentd
+	keepdir /var/log/spice-vdagentd
+
+	newinitd "${FILESDIR}/${PN}.initd" "${PN}"
+	newconfd "${FILESDIR}/${PN}.confd" "${PN}"
+}
+
+pkg_postinst() {
+	elog "Make sure that the User level driver support kernel module 'uinput' is loaded"
+	elog "if built as a module before starting the vdagent daemon."
+}