Added CC variable, bug #243600. Removed old version.

Package-Manager: portage-2.2_rc12/cvs/Linux 2.6.27-gentoo x86_64

1 files changed, 59 insertions, 0 deletions

diff --git a/app-i18n/xvnkb/xvnkb-0.2.9a-r1.ebuild b/app-i18n/xvnkb/xvnkb-0.2.9a-r1.ebuild
new file mode 100644
index 000000000000..b2325a48e592
--- /dev/null
+++ b/app-i18n/xvnkb/xvnkb-0.2.9a-r1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-i18n/xvnkb/xvnkb-0.2.9a-r1.ebuild,v 1.1 2008/10/30 15:27:52 matsuu Exp $
+
+inherit eutils multilib toolchain-funcs
+
+IUSE="truetype spell"
+
+DESCRIPTION="Vietnamese input keyboard for X"
+SRC_URI="http://xvnkb.sourceforge.net/${P}.tar.bz2"
+HOMEPAGE="http://xvnkb.sourceforge.net/"
+
+LICENSE="GPL-2"
+
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+RDEPEND="x11-libs/libX11
+	truetype? ( virtual/xft )"
+DEPEND="${RDEPEND}
+	x11-proto/xproto"
+
+src_compile() {
+	local myconf
+
+	tc-export CC
+
+	use spell || myconf="${myconf} --no-spellcheck"
+	use truetype || myconf="${myconf} --no-xft"
+
+	# *not* autotools
+	./configure \
+		--use-extstroke ${myconf} \
+		|| die "./configure failed"
+
+	emake || die "emake failed"
+}
+
+src_install() {
+	dobin xvnkb
+	dobin tools/xvnkb_ctrl
+
+	dolib xvnkb.so.${PV}
+	dosym xvnkb.so.${PV} /usr/$(get_libdir)/xvnkb.so
+
+	dodoc ChangeLog AUTHORS THANKS TODO README* doc/*
+	docinto scripts; dodoc scripts/*
+	docinto contrib; dodoc contrib/*
+}
+
+pkg_postinst() {
+	elog "Remember to"
+	elog "$ export LANG=en_US.UTF-8"
+	elog "(or any other UTF-8 locale) and"
+	elog "$ export LD_PRELOAD=${DESTTREE}/lib/xvnkb.so"
+	elog "before starting X Window"
+	elog "More documents are in /usr/share/doc/${PF}"
+	ewarn "Programs with suid/sgid will have LD_PRELOAD cleared"
+	ewarn "You have to unset suid/sgid to use with xvnkb"
+}