Bump 8.1 too

Package-Manager: portage-2.2.0_alpha13/cvs/Linux x86_64

4 files changed, 202 insertions, 2 deletions

diff --git a/dev-db/postgresql-base/ChangeLog b/dev-db/postgresql-base/ChangeLog
index 7196639d3c36..a853b70a946c 100644
--- a/dev-db/postgresql-base/ChangeLog
+++ b/dev-db/postgresql-base/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-db/postgresql-base
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-db/postgresql-base/ChangeLog,v 1.87 2011/01/04 19:22:51 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-db/postgresql-base/ChangeLog,v 1.88 2011/01/06 12:23:35 patrick Exp $
+
+*postgresql-base-8.1.23 (06 Jan 2011)
+
+  06 Jan 2011; Patrick Lauer <patrick@gentoo.org>
+  +postgresql-base-8.1.23.ebuild:
+  Bump 8.1 too
 
 *postgresql-base-9.0.2 (04 Jan 2011)
 *postgresql-base-8.4.6 (04 Jan 2011)
diff --git a/dev-db/postgresql-base/postgresql-base-8.1.23.ebuild b/dev-db/postgresql-base/postgresql-base-8.1.23.ebuild
new file mode 100644
index 000000000000..fbd612c8583f
--- /dev/null
+++ b/dev-db/postgresql-base/postgresql-base-8.1.23.ebuild
@@ -0,0 +1,144 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-db/postgresql-base/postgresql-base-8.1.23.ebuild,v 1.1 2011/01/06 12:23:35 patrick Exp $
+
+EAPI="2"
+
+WANT_AUTOMAKE="none"
+
+inherit eutils multilib versionator autotools
+
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~s390 ~sh ~sparc ~x86"
+
+DESCRIPTION="PostgreSQL libraries and clients"
+HOMEPAGE="http://www.postgresql.org/"
+SRC_URI="mirror://postgresql/source/v${PV}/postgresql-${PV}.tar.bz2"
+LICENSE="POSTGRESQL"
+SLOT="$(get_version_component_range 1-2)"
+IUSE_LINGUAS="
+	linguas_af linguas_cs linguas_de linguas_es linguas_fa linguas_fr
+	linguas_hr linguas_hu linguas_it linguas_ko linguas_nb linguas_pl
+	linguas_pt_BR linguas_ro linguas_ru linguas_sk linguas_sl linguas_sv
+	linguas_tr linguas_zh_CN linguas_zh_TW"
+IUSE="doc kerberos nls pam pg-intdatetime readline ssl threads zlib ${IUSE_LINGUAS}"
+RESTRICT="test"
+
+wanted_languages() {
+	for u in ${IUSE_LINGUAS} ; do
+		use $u && echo -n "${u#linguas_} "
+	done
+}
+
+RDEPEND="kerberos? ( virtual/krb5 )
+	pam? ( virtual/pam )
+	readline? ( >=sys-libs/readline-4.1 )
+	ssl? ( >=dev-libs/openssl-0.9.6-r1 )
+	zlib? ( >=sys-libs/zlib-1.1.3 )
+	>=app-admin/eselect-postgresql-0.3
+	virtual/libintl
+	!!dev-db/postgresql-libs
+	!!dev-db/postgresql-client
+	!!dev-db/libpq
+	!!dev-db/postgresql"
+DEPEND="${RDEPEND}
+	sys-devel/flex
+	>=sys-devel/bison-1.875
+	nls? ( sys-devel/gettext )"
+PDEPEND="doc? ( ~dev-db/postgresql-docs-${PV} )"
+
+S="${WORKDIR}/postgresql-${PV}"
+
+src_prepare() {
+
+	epatch "${FILESDIR}/postgresql-${SLOT}-common.patch" \
+		"${FILESDIR}/postgresql-${SLOT}-base.patch" \
+		"${FILESDIR}/postgresql-8.x-relax_ssl_perms.patch"
+
+	# to avoid collision - it only should be installed by server
+	rm "${S}/src/backend/nls.mk"
+
+	# because psql/help.c includes the file
+	ln -s "${S}/src/include/libpq/pqsignal.h" "${S}/src/bin/psql/"
+
+	eautoconf
+}
+
+src_configure() {
+	export LDFLAGS_SL="${LDFLAGS}"
+	econf --prefix=/usr/$(get_libdir)/postgresql-${SLOT} \
+		--datadir=/usr/share/postgresql-${SLOT} \
+		--sysconfdir=/etc/postgresql-${SLOT} \
+		--includedir=/usr/include/postgresql-${SLOT} \
+		--with-locale-dir=/usr/share/postgresql-${SLOT}/locale \
+		--mandir=/usr/share/postgresql-${SLOT}/man \
+		--without-docdir \
+		--without-tcl \
+		--without-perl \
+		--without-python \
+		$(use_with kerberos krb5) \
+		"$(use_enable nls nls "$(wanted_languages)")" \
+		$(use_with pam) \
+		$(use_enable pg-intdatetime integer-datetimes ) \
+		$(use_with readline) \
+		$(use_with ssl openssl) \
+		$(use_enable threads thread-safety) \
+		$(use_with zlib) \
+		|| die "configure failed"
+}
+
+src_compile() {
+	emake || die "emake failed"
+
+	cd "${S}/contrib"
+	emake || die "emake failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	insinto /usr/include/postgresql-${SLOT}/postmaster
+	doins "${S}"/src/include/postmaster/*.h
+	dodir /usr/share/postgresql-${SLOT}/man/man1
+	tar -zxf "${S}/doc/man.tar.gz" -C "${D}"/usr/share/postgresql-${SLOT}/man man1/{ecpg,pg_config}.1
+
+	rm "${D}/usr/share/postgresql-${SLOT}/man/man1"/{initdb,ipcclean,pg_controldata,pg_ctl,pg_resetxlog,pg_restore,postgres,postmaster}.1
+	dodoc README HISTORY doc/{README.*,TODO,bug.template}
+
+	cd "${S}/contrib"
+	emake DESTDIR="${D}" install || die "emake install failed"
+	cd "${S}"
+
+	dodir /etc/eselect/postgresql/slots/${SLOT}
+
+	IDIR="/usr/include/postgresql-${SLOT}"
+	cat > "${D}/etc/eselect/postgresql/slots/${SLOT}/base" <<-__EOF__
+postgres_ebuilds="\${postgres_ebuilds} ${PF}"
+postgres_prefix=/usr/$(get_libdir)/postgresql-${SLOT}
+postgres_datadir=/usr/share/postgresql-${SLOT}
+postgres_bindir=/usr/$(get_libdir)/postgresql-${SLOT}/bin
+postgres_symlinks=(
+	${IDIR} /usr/include/postgresql
+	${IDIR}/libpq-fe.h /usr/include/libpq-fe.h
+	${IDIR}/pg_config_manual.h /usr/include/pg_config_manual.h
+	${IDIR}/libpq /usr/include/libpq
+	${IDIR}/postgres_ext.h /usr/include/postgres_ext.h
+)
+__EOF__
+
+	cat >"${T}/50postgresql-96-${SLOT}" <<-__EOF__
+		LDPATH=/usr/$(get_libdir)/postgresql-${SLOT}/$(get_libdir)
+		MANPATH=/usr/share/postgresql-${SLOT}/man
+	__EOF__
+	doenvd "${T}/50postgresql-96-${SLOT}"
+
+	keepdir /etc/postgresql-${SLOT}
+}
+
+pkg_postinst() {
+	eselect postgresql update
+	[[ "$(eselect postgresql show)" = "(none)" ]] && eselect postgresql set ${SLOT}
+	elog "If you need a global psqlrc-file, you can place it in '${ROOT}/etc/postgresql-${SLOT}/'."
+}
+
+pkg_postrm() {
+	eselect postgresql update
+}
diff --git a/dev-db/postgresql-docs/ChangeLog b/dev-db/postgresql-docs/ChangeLog
index 73d66ee42e57..524417c8ec87 100644
--- a/dev-db/postgresql-docs/ChangeLog
+++ b/dev-db/postgresql-docs/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-db/postgresql-docs
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-db/postgresql-docs/ChangeLog,v 1.71 2011/01/04 19:23:22 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-db/postgresql-docs/ChangeLog,v 1.72 2011/01/06 12:24:06 patrick Exp $
+
+*postgresql-docs-8.1.23 (06 Jan 2011)
+
+  06 Jan 2011; Patrick Lauer <patrick@gentoo.org>
+  +postgresql-docs-8.1.23.ebuild:
+  Bump 8.1 too
 
 *postgresql-docs-9.0.2 (04 Jan 2011)
 *postgresql-docs-8.4.6 (04 Jan 2011)
diff --git a/dev-db/postgresql-docs/postgresql-docs-8.1.23.ebuild b/dev-db/postgresql-docs/postgresql-docs-8.1.23.ebuild
new file mode 100644
index 000000000000..293eb3e58002
--- /dev/null
+++ b/dev-db/postgresql-docs/postgresql-docs-8.1.23.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-db/postgresql-docs/postgresql-docs-8.1.23.ebuild,v 1.1 2011/01/06 12:24:06 patrick Exp $
+
+inherit versionator
+
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~s390 ~sh ~sparc ~x86"
+
+DESCRIPTION="PostgreSQL documentation"
+HOMEPAGE="http://www.postgresql.org/"
+SRC_URI="mirror://postgresql/source/v${PV}/postgresql-${PV}.tar.bz2"
+LICENSE="POSTGRESQL"
+SLOT="$(get_version_component_range 1-2)"
+IUSE=""
+
+DEPEND=""
+RDEPEND=""
+RESTRICT="test"
+
+S="${WORKDIR}/postgresql-${PV}"
+
+src_compile() {
+	:
+}
+
+src_install() {
+	dodir /usr/share/doc/${PF}/html
+	tar -zxf "${S}/doc/postgres.tar.gz" -C "${D}/usr/share/doc/${PF}/html"
+	fowners root:0 -R /usr/share/doc/${PF}/html
+	cd "${S}/doc"
+	docinto FAQ_html
+	dodoc src/FAQ/*
+	docinto sgml
+	dodoc src/sgml/*.{sgml,dsl}
+	docinto sgml/ref
+	dodoc src/sgml/ref/*.sgml
+	docinto TODO.detail
+	dodoc TODO.detail/*
+
+	dodir /etc/eselect/postgresql/slots/${SLOT}
+	{
+		echo "postgres_ebuilds=\"\${postgres_ebuilds} ${PF}\""
+	} >"${D}/etc/eselect/postgresql/slots/${SLOT}/docs"
+}