bump; use-flag cgi removed, support removed in source; useflag sdk removed, --with-skd enabled by default, will not compile without sdk support

Package-Manager: portage-2.2.1/cvs/Linux i686
Manifest-Sign-Key: 0x34C2808A

1 files changed, 85 insertions, 0 deletions

diff --git a/dev-libs/tntnet/tntnet-2.2.1.ebuild b/dev-libs/tntnet/tntnet-2.2.1.ebuild
new file mode 100644
index 000000000000..6394d07371b6
--- /dev/null
+++ b/dev-libs/tntnet/tntnet-2.2.1.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/tntnet/tntnet-2.2.1.ebuild,v 1.1 2014/01/23 21:05:00 hd_brummy Exp $
+
+EAPI=5
+
+inherit autotools eutils
+
+DESCRIPTION="Modular, multithreaded webapplicationserver extensible with C++"
+HOMEPAGE="http://www.tntnet.org/"
+SRC_URI="http://www.tntnet.org/download/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~sparc ~x86"
+IUSE="doc gnutls server ssl examples"
+
+RDEPEND=">=dev-libs/cxxtools-2.2.1
+	sys-libs/zlib[minizip]
+	ssl? (
+		gnutls? (
+			>=net-libs/gnutls-1.2.0
+			dev-libs/libgcrypt
+		)
+		!gnutls? ( dev-libs/openssl )
+	)"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	examples? ( app-arch/zip )"
+
+src_prepare() {
+	# Both fixed in the next release
+	epatch "${FILESDIR}"/${PN}-2.0-zlib-minizip.patch
+	rm framework/common/{ioapi,unzip}.[ch] || die
+
+	eautoreconf
+
+	sed -i -e 's:@localstatedir@:/var:' etc/tntnet/tntnet.xml.in || die
+}
+
+src_configure() {
+	local myconf=""
+
+	# Prefer gnutls above SSL
+	if use gnutls; then
+		einfo "Using gnutls for ssl support."
+		myconf="${myconf} --with-ssl=gnutls"
+	elif use ssl; then
+		einfo "Using openssl for ssl support."
+		myconf="${myconf} --with-ssl=openssl"
+	else
+		myconf="${myconf} --with-ssl=no"
+	fi
+
+	# default enabled, will not compile without sdk
+	myconf="${myconf} --with-sdk"
+
+	econf \
+		$(use_with server) \
+		${myconf}
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+
+	dodoc AUTHORS ChangeLog README TODO
+	if use doc; then
+		dodoc doc/*.pdf || die
+	fi
+
+	if use examples; then
+		cd "${S}/sdk/demos"
+		emake clean
+		rm -rf .deps */.deps .libs */.libs
+		cd "${S}"
+
+		insinto /usr/share/doc/${PF}/examples
+		doins -r sdk/demos/* || die
+	fi
+
+	if use server; then
+		rm -f "${D}/etc/init.d/tntnet"
+		newinitd "${FILESDIR}/tntnet.initd" tntnet
+	fi
+}