Add new revision to be compatible with boost-1.48. Thanks to Arfrever

Package-Manager: portage-2.2.0_alpha84/cvs/Linux x86_64

3 files changed, 77 insertions, 5 deletions

diff --git a/dev-python/cgkit/ChangeLog b/dev-python/cgkit/ChangeLog
index aa06da3e0e45..b7bbdeaa3d3f 100644
--- a/dev-python/cgkit/ChangeLog
+++ b/dev-python/cgkit/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/cgkit
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/cgkit/ChangeLog,v 1.31 2011/05/27 12:32:04 flameeyes Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/cgkit/ChangeLog,v 1.32 2012/01/24 20:45:42 hwoarang Exp $
+
+*cgkit-2.0.0_alpha9-r1 (24 Jan 2012)
+
+  24 Jan 2012; Markos Chandras <hwoarang@gentoo.org>
+  +cgkit-2.0.0_alpha9-r1.ebuild, cgkit-2.0.0_alpha9.ebuild:
+  Add new revision to be compatible with boost-1.48. Thanks to Arfrever
 
   27 May 2011; Diego E. Pettenò <flameeyes@gentoo.org>
   cgkit-2.0.0_alpha9.ebuild:
diff --git a/dev-python/cgkit/cgkit-2.0.0_alpha9-r1.ebuild b/dev-python/cgkit/cgkit-2.0.0_alpha9-r1.ebuild
new file mode 100644
index 000000000000..526f80418d3f
--- /dev/null
+++ b/dev-python/cgkit/cgkit-2.0.0_alpha9-r1.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/cgkit/cgkit-2.0.0_alpha9-r1.ebuild,v 1.1 2012/01/24 20:45:42 hwoarang Exp $
+
+EAPI="3"
+PYTHON_DEPEND="2"
+
+inherit distutils
+
+MY_P="${P/_/}"
+
+DESCRIPTION="Python library for creating 3D images"
+HOMEPAGE="http://cgkit.sourceforge.net"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
+
+RDEPEND=">=dev-libs/boost-1.48[python]
+	dev-python/pyprotocols
+	dev-python/pyopengl
+	dev-python/pygame
+	dev-python/imaging
+	3ds? ( media-libs/lib3ds )"
+DEPEND="${RDEPEND}
+	dev-util/scons"
+
+LICENSE="LGPL-2.1 MPL-1.1 GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="3ds"
+
+S="${WORKDIR}/${MY_P}"
+
+pkg_setup() {
+	python_set_active_version 2
+	python_pkg_setup
+}
+
+src_prepare() {
+	distutils_src_prepare
+
+	sed -e "s/fPIC/fPIC\",\"${CFLAGS// /\",\"}/" -i supportlib/SConstruct
+	cp config_template.cfg config.cfg
+	echo "BOOST_LIB = 'boost_python-${PYTHON_ABI}'" >> config.cfg
+	echo "LIBS += ['GL', 'GLU', 'glut']" >> config.cfg
+	if use 3ds; then
+		echo "LIB3DS_AVAILABLE = True" >> config.cfg
+	fi
+
+	sed -e "s:INC_DIRS = \[\]:INC_DIRS = \['/usr/include'\]:" -i setup.py
+
+	sed -e "160s/as/as_/;168s/as/as_/" -i cgkit/flockofbirds.py
+}
+
+src_compile() {
+	pushd supportlib > /dev/null
+	scons ${MAKEOPTS}
+	popd > /dev/null
+
+	distutils_src_compile
+}
+
+src_test() {
+	cd unittests
+	# Remove failing tests due to non-existing files
+	rm test_maimport.py test_mayaascii.py test_mayabinary.py test_ri.py test_slparams.py
+	PYTHONPATH="$(ls -d ../build/lib*)" "$(PYTHON)" all.py || die "Tests failed"
+}
diff --git a/dev-python/cgkit/cgkit-2.0.0_alpha9.ebuild b/dev-python/cgkit/cgkit-2.0.0_alpha9.ebuild
index f600d466b619..4e0ec714d031 100644
--- a/dev-python/cgkit/cgkit-2.0.0_alpha9.ebuild
+++ b/dev-python/cgkit/cgkit-2.0.0_alpha9.ebuild
@@ -1,6 +1,6 @@
-# Copyright 1999-2011 Gentoo Foundation
+# Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/cgkit/cgkit-2.0.0_alpha9.ebuild,v 1.5 2011/05/27 12:32:04 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/cgkit/cgkit-2.0.0_alpha9.ebuild,v 1.6 2012/01/24 20:45:42 hwoarang Exp $
 
 EAPI="3"
 PYTHON_DEPEND="2"
@@ -14,7 +14,7 @@ HOMEPAGE="http://cgkit.sourceforge.net"
 SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
 
 RDEPEND="dev-python/pyrex
-	dev-libs/boost[python]
+	<dev-libs/boost-1.48[python]
 	dev-python/pyprotocols
 	dev-python/pyopengl
 	dev-python/pygame