Version bump.

Package-Manager: portage-2.1.9.25/cvs/Linux x86_64

6 files changed, 173 insertions, 4 deletions

diff --git a/dev-ruby/bones/ChangeLog b/dev-ruby/bones/ChangeLog
index 28d7710106d5..2be3219f0dfe 100644
--- a/dev-ruby/bones/ChangeLog
+++ b/dev-ruby/bones/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-ruby/bones
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-ruby/bones/ChangeLog,v 1.11 2011/01/28 08:03:11 graaff Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/bones/ChangeLog,v 1.12 2011/01/28 08:06:43 graaff Exp $
+
+*bones-3.6.2 (28 Jan 2011)
+
+  28 Jan 2011; Hans de Graaff <graaff@gentoo.org> +bones-3.6.2.ebuild:
+  Version bump.
 
   28 Jan 2011; Hans de Graaff <graaff@gentoo.org> -bones-3.5.2.ebuild,
   -bones-3.5.5.ebuild:
diff --git a/dev-ruby/bones/bones-3.6.2.ebuild b/dev-ruby/bones/bones-3.6.2.ebuild
new file mode 100644
index 000000000000..b202013e8ddd
--- /dev/null
+++ b/dev-ruby/bones/bones-3.6.2.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/bones/bones-3.6.2.ebuild,v 1.1 2011/01/28 08:06:43 graaff Exp $
+
+EAPI=2
+
+USE_RUBY="ruby18 ruby19 jruby"
+
+RUBY_FAKEGEM_TASK_TEST="spec:specdoc"
+
+RUBY_FAKEGEM_TASK_DOC="doc:rdoc"
+RUBY_FAKEGME_DOCDIR="doc"
+
+RUBY_FAKEGEM_EXTRADOC="History.txt README.rdoc"
+
+RUBY_FAKEGEM_EXTRAINSTALL="default version.txt"
+
+inherit ruby-fakegem
+
+DESCRIPTION="Tool that creates new Ruby projects from a code skeleton"
+HOMEPAGE="http://github.com/TwP/bones"
+
+IUSE=""
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+ruby_add_rdepend "
+	>=dev-ruby/loquacious-1.7.0
+	>=dev-ruby/little-plugger-1.1.2-r1
+	>=dev-ruby/rake-0.8.7"
+
+ruby_add_bdepend "
+	test? (
+		>=dev-ruby/bones-extras-1.2.2
+		>=dev-ruby/rspec-1.2.9:0
+	)
+	doc? ( >=dev-ruby/bones-extras-1.2.2 )"
+
+all_ruby_prepare() {
+	# Avoid double --format specdoc option which causes problems for rspec.
+	sed -i -e 's/--format specdoc//' Rakefile || die
+}
diff --git a/dev-ruby/json/ChangeLog b/dev-ruby/json/ChangeLog
index c118d98ef3ec..bb3f4bfcd9c6 100644
--- a/dev-ruby/json/ChangeLog
+++ b/dev-ruby/json/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-ruby/json
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-ruby/json/ChangeLog,v 1.56 2011/01/23 11:33:31 xarthisius Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/json/ChangeLog,v 1.57 2011/01/28 08:09:15 graaff Exp $
+
+*json-1.5.1 (28 Jan 2011)
+
+  28 Jan 2011; Hans de Graaff <graaff@gentoo.org> +json-1.5.1.ebuild:
+  Version bump.
 
   23 Jan 2011; Kacper Kowalik <xarthisius@gentoo.org> json-1.4.6.ebuild:
   ppc64 stable wrt #343473
diff --git a/dev-ruby/json/json-1.5.1.ebuild b/dev-ruby/json/json-1.5.1.ebuild
new file mode 100644
index 000000000000..3c3dd800fe7f
--- /dev/null
+++ b/dev-ruby/json/json-1.5.1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/json/json-1.5.1.ebuild,v 1.1 2011/01/28 08:09:15 graaff Exp $
+
+EAPI=2
+USE_RUBY="ruby18 ree18 ruby19 jruby"
+
+RUBY_FAKEGEM_TASK_DOC="doc"
+RUBY_FAKEGEM_EXTRADOC="CHANGES TODO README"
+RUBY_FAKEGEM_DOCDIR="doc"
+
+inherit multilib ruby-fakegem
+
+DESCRIPTION="A JSON implementation as a Ruby extension."
+HOMEPAGE="http://json.rubyforge.org/"
+LICENSE="|| ( Ruby GPL-2 )"
+SRC_URI="mirror://rubygems/${P}.gem"
+
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris ~x86-solaris"
+SLOT="0"
+IUSE=""
+
+RDEPEND="${RDEPEND}"
+DEPEND="${DEPEND}
+	dev-util/ragel"
+
+ruby_add_bdepend "dev-ruby/rake
+	test? ( virtual/ruby-test-unit )"
+
+all_ruby_prepare() {
+	# Avoid building the extension twice!
+	# And use rdoc instead of sdoc which we don't have packaged
+	sed -i \
+		-e 's| => :compile_ext||' \
+		-e 's| => :clean||' \
+		-e 's|sdoc|rdoc|' \
+		Rakefile || die "rakefile fix failed"
+}
+
+each_ruby_compile() {
+	# Since 1.5.0 a Java extension is provided but it does not compile.
+	if [[ $(basename ${RUBY}) != "jruby" ]]; then
+		${RUBY} -S rake compile_ext || die "extension compile failed"
+	fi
+}
+
+each_ruby_test() {
+	JSON=pure \
+	${RUBY} -Iext:lib -S testrb tests/*.rb || die "pure ruby tests failed"
+
+	if [[ $(basename ${RUBY}) != "jruby" ]]; then
+		JSON=ext \
+		${RUBY} -Iext:lib -S testrb tests/*.rb || die "ext ruby tests failed"
+	fi
+}
+
+each_ruby_install() {
+	each_fakegem_install
+	if [[ $(basename ${RUBY}) != "jruby" ]]; then
+		ruby_fakegem_newins ext/json/ext/generator$(get_modname) lib/json/ext/generator$(get_modname)
+		ruby_fakegem_newins ext/json/ext/parser$(get_modname) lib/json/ext/parser$(get_modname)
+	fi
+}
diff --git a/dev-ruby/rdiscount/ChangeLog b/dev-ruby/rdiscount/ChangeLog
index 639d3e01a7f7..51eff0986658 100644
--- a/dev-ruby/rdiscount/ChangeLog
+++ b/dev-ruby/rdiscount/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-ruby/rdiscount
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-ruby/rdiscount/ChangeLog,v 1.1 2010/09/14 18:58:10 graaff Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/rdiscount/ChangeLog,v 1.2 2011/01/28 08:10:52 graaff Exp $
+
+*rdiscount-1.6.8 (28 Jan 2011)
+
+  28 Jan 2011; Hans de Graaff <graaff@gentoo.org> +rdiscount-1.6.8.ebuild:
+  Version bump.
 
 *rdiscount-1.6.5 (14 Sep 2010)
 
diff --git a/dev-ruby/rdiscount/rdiscount-1.6.8.ebuild b/dev-ruby/rdiscount/rdiscount-1.6.8.ebuild
new file mode 100644
index 000000000000..46d91cbf6c66
--- /dev/null
+++ b/dev-ruby/rdiscount/rdiscount-1.6.8.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/rdiscount/rdiscount-1.6.8.ebuild,v 1.1 2011/01/28 08:10:52 graaff Exp $
+
+EAPI=2
+
+# Has a native extension without jruby support.
+USE_RUBY="ruby18 ree18"
+
+RUBY_FAKEGEM_TASK_TEST="test:unit"
+
+RUBY_FAKEGEM_TASK_DOC="doc man"
+RUBY_FAKEGEM_EXTRADOC="README.markdown"
+
+inherit multilib ruby-fakegem
+
+DESCRIPTION="Implementation of John Gruber's Markdown"
+HOMEPAGE="http://github.com/rtomayko/rdiscount"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE=""
+
+ruby_add_bdepend "doc? ( app-text/ronn )"
+
+all_ruby_prepare() {
+	# Hanna is broken for us and therefore we don't have it in portage.
+	sed -i -e 's/hanna/rdoc/' Rakefile || die
+
+	# Remove rule that will force a rebuild when running tests.
+	sed -i -e "/task 'test:unit' => \[:build\]/d" Rakefile || die
+}
+
+each_ruby_configure() {
+	${RUBY} -Cext extconf.rb || die
+}
+
+each_ruby_compile() {
+	emake -Cext || die
+	cp ext/*$(get_modname) lib/ || die
+}
+
+all_ruby_install() {
+	all_fakegem_install
+
+	doman man/rdiscount.1
+}